build.gradle

buildscript {
    repositories {
        jcenter()
        maven { url = "http://files.minecraftforge.net/maven" }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
        classpath 'com.github.jengelman.gradle.plugins:shadow:2.0.2'
    }
}

apply plugin: 'com.github.johnrengelman.shadow'
apply plugin: 'net.minecraftforge.gradle.forge'
apply plugin: 'java'

targetCompatibility = sourceCompatibility = JavaVersion.VERSION_1_8

version = "1.12.2-0.3.1"
group = "com.derimagia.forgeslack"
archivesBaseName = "forgeslack"

repositories {
    maven { url = "https://jitpack.io" }
}

minecraft {
    version = "1.12.2-14.23.2.2611"
    runDir = "run"

    // snapshot_YYYYMMDD   snapshot are built nightly.
    // stable_#            stables are built at the discretion of the MCP team.
    mappings = "snapshot_20171003"

    replaceIn "ForgeSlack.java"
    replace "@VERSION@", project.version
}

dependencies {
    compile group: 'com.github.allbegray', name: 'slack-api', version: 'v1.4.0.RELEASE'

    // Manually include `org.slf4j` for slack-api
    compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.25'
    compile group: 'org.slf4j', name: 'slf4j-simple', version: '1.7.25'
}

processResources {
    // this will ensure that this task is redone when the versions change.
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'

        // replace version and mcversion
        expand 'version': project.version, 'mcversion': project.minecraft.version
    }

    // copy everything else, thats not the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

shadowJar {
    classifier = ''
    // Can't relocate this because of something with AsyncHttpClientConfigDefaults:ASYNC_CLIENT_CONFIG_ROOT
    // but most likely this won't matter because these libraries aren't probably used elsewhere.
    // relocate "allbegray.slack", "com.derimagia.lib.com.github.allbegray"
    // relocate "org.asynchttpclient", "com.derimagia.lib.org.asynchttpclient"
    relocate "com.fasterxml.jackson.core", "com.derimagia.lib.com.fasterxml.jackson.core"
    relocate "org.apache.http", "com.derimagia.lib.org.apache.http"
    relocate "org.apache.commons", "com.derimagia.lib.org.apache.commons"
    relocate "org.slf4j", "com.derimagia.lib.org.slf4j"
    relocate "io.netty", "com.derimagia.lib.io.netty"
    relocate "com.typesafe", "com.derimagia.lib.com.typesafe"
    relocate "com.fasterxml", "com.derimagia.lib.com.fasterxml"
    relocate "javassist", "com.derimagia.lib.javassist"
}

reobf {
    shadowJar { mappingType = 'SEARGE' }
}