Conditional statements with && and ||?

[alshdavid]

I'd like to use an && or || in my build script to reduce the size of my if statement responsible for mapping os/arch env variables to Cargo arguments

profile := env_var_or_default("profile", "debug")
os := env_var_or_default("os", "")
arch := env_var_or_default("arch", "")

target := \
if \
  os + arch == "linuxamd64" || os() + arch == "linuxamd64" || os + arch() == "linuxamd64" || os() + arch() == "linuxamd64" { "x86_64-unknown-linux-gnu" } \
else if \
  os + arch == "linuxarm64" || os() + arch == "linuxarm64" || os + arch() == "linuxarm64" || os() + arch() == "linuxarm64" { "aarch64-unknown-linux-gnu" } \
else if \
  os + arch == "macosamd64" || os() + arch == "macosamd64" || os + arch() == "macosamd64" || os() + arch() == "macosamd64" { "x86_64-apple-darwin" } \
else if\
  os + arch == "macosarm64" || os() + arch == "macosarm64" || os + arch() == "macosarm64" || os() + arch() == "macosarm64" { "aarch64-apple-darwin" } \
else if \
  os + arch == "windowsamd64" || os() + arch == "windowsamd64" || os + arch() == "windowsamd64" || os() + arch() == "windowsamd64" { "x86_64-pc-windows-msvc" } \
else if \
  os + arch == "windowsarm64" || os() + arch == "windowsarm64" || os + arch() == "windowsarm64" || os() + arch() == "windowsarm64" { "aarch64-pc-windows-msvc" } \
else \
  {"INVALID"}

build:
  cargo build \
    {{ if profile != "debug" { "--profile " + profile } else { "" } }} \
    {{ if target != "" { "--target " + target } else { "" } }}

os=linux arch=arm64 just build

> cargo build --target aarch64-unknown-linux-gnu

However I can't seem to find a way to do this. I can use a gigantic if statement however that's pretty messy.

Also can I create multi-line if statements without newline escape characters? \

[casey]

This isn't yet supported, but I think it would be reasonable to add || and && in conditions.

[alshdavid]

Thanks! For reference, the solution to my above problem using just today looks like this:

Objective

os=linux arch=arm64 just build
> cargo build --target aarch64-unknown-linux-gnu

os=linux arch=arm64 profile=release just build
> cargo build --target aarch64-unknown-linux-gnu --profile release

arch=amd64 profile=debug just build
> cargo build --target x86_64-unknown-linux-gnu

justfile

profile := env_var_or_default("profile", "debug")

# Map OS to "macos" "windows" "linux"
os := \
if \
  env_var_or_default("os", "") == "Windows_NT" { "windows" } \
else if \
  env_var_or_default("os", "") != "" { env_var("os") } \
else \
  { os() }

# Map Arch to "arm64" "amd64"
arch := \
if \
  env_var_or_default("arch", "") != "" { env_var("arch") } \
else if \
  arch() == "x86_64" { "amd64" } \
else if \
  arch() == "aarch64" { "arm64" } \
else \
  { arch() }

# Map OS and Arch to Cargo target
target := \
if \
  os + arch == "linuxamd64" { "x86_64-unknown-linux-gnu" } \
else if \
  os + arch == "linuxarm64" { "aarch64-unknown-linux-gnu" } \
else if \
  os + arch == "macosamd64" { "x86_64-apple-darwin" } \
else if\
  os + arch == "macosarm64" { "aarch64-apple-darwin" } \
else if \
  os + arch == "windowsamd64" { "x86_64-pc-windows-msvc" } \
else if \
  os + arch == "windowsarm64" { "aarch64-pc-windows-msvc" } \
else \
  { env_var_or_default("target", "debug") }

build:
  cargo build \
    {{ if profile != "debug" { "--profile " + profile } else { "" } }} \
    {{ if target != "" { "--target " + target } else { "" } }}