Way to make a re-usable recipe code block?

[johnalotoski]

Is there a way to define a re-usable code block to be used in multiple recipes from within the Justfile?

That would be nice to reduce the boiler plate of some just recipes that share common script code, but this common code can't be relegated to a subshell or called separately as another dependency.

I found I can use a multiline just string, and then source it as a file redirect from each recipe, something like:

common := '''
  # just param subst from the calling recipe of this multiline string won't work:
  # ARG1={{ENV}}

  # So use bash shell cli arg indexing instead
  ARG1="\${1:-}"

  # Do common stuff ...
'''

recipe1 ENV:
  #!/usr/bin/env bash
  source <(echo "{{common}}")
  # Do some stuff...

recipe2 ENV:
  #!/usr/bin/env bash
  source <(echo "{{common}}")
  # Do some other stuff...

I could also source an external file for boilerplate bits, but would rather not do that.

I could use triple backticks for multiline command evaluation instead possibly, but that context gets the default Justfile shell which differs from the shell I'd like it to have, and it's more complicated than necessary for what I'd like to do.

Ideally, I could define a "just block" of code, and place it anywhere in the justfile for a direct substitution, like:

common := <justblock start delimiter>
  ARG1={{ENV}}

  # Do common stuff ...
<justblock end delimiter>

recipe1 ENV:
  #!/usr/bin/env bash
  {{common}}
  # Do some stuff...

recipe2 ENV:
  #!/usr/bin/env bash
  {{common}}
  # Do some other stuff...

I don't think that exists?

Thanks for any feedback.

[laniakea64]

For those examples you could use set positional-arguments -

set positional-arguments

common := '''
  ARG1="$1"

  # Do common stuff ...
'''

recipe1 ENV:
  #!/usr/bin/env bash
  {{common}}
  # Do some stuff...

recipe2 ENV:
  #!/usr/bin/env bash
  {{common}}
  # Do some other stuff...

Does this work for your case?

[johnalotoski]

Hi @laniakea64, yes, that does work for me and the direct block inclusion works as expected also without the extra escaping.

When I was initially doing some testing, I had commented some code out which included a # {{multilineBlockRef}} line, and this was causing a failure without my realizing it, leading me to think block references weren't working in a straightforward intuitive manner.

Now I see it was my mistake and it all makes sense. Thanks for the sanity check :)

[casey]

I wish there was a nicer way of doing this T_T

[chopper2000uk]

Probably not it's intended use but [script('cat')] can also be used.

set unstable

[private]
[script('cat')]
func_lib:
  say_hello() {
    echo "Hello $1"
  }

[script]
foo:
  source <(just func_lib)  
  say_hello 'foo'

[script]
bar:
  source <(just func_lib)  
  say_hello 'bar'