build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven { url { 'https://plugins.gradle.org/m2/' }}
    }
    dependencies {
        classpath "org.jfrog.buildinfo:build-info-extractor-gradle:4.0.0"
        classpath "org.sonarsource.scanner.gradle:sonarqube-gradle-plugin:1.2"
        classpath 'com.netflix.nebula:nebula-release-plugin:4.2.0'
        classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.8.0"
    }
}

apply plugin: 'maven'
apply plugin: 'java'
apply plugin: 'nebula.nebula-release'
apply plugin: 'signing'
apply plugin: 'io.codearte.nexus-staging'

group = 'com.cars'
archivesBaseName = 'docker-secrets'

repositories {
  jcenter()
}


sourceCompatibility = 1.7
targetCompatibility = 1.7

dependencies {
	compile 'org.slf4j:slf4j-api:1.7.14'
	testCompile 'junit:junit:4.12'
}

task javadocJar(type: Jar) {
  classifier = 'javadoc'
  from javadoc
}

task sourcesJar(type: Jar, dependsOn: classes) {
	classifier = 'sources'
	from sourceSets.main.allSource
}

artifacts {
  archives javadocJar, sourcesJar
}

signing {
  sign configurations.archives
}

uploadArchives {
  repositories {
    mavenDeployer {
      beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

			def user = hasProperty('ossrhUsername') ? ossrhUsername : System.getenv('ossrhUsername')
			def pass = hasProperty('ossrhPassword') ? ossrhPassword : System.getenv('ossrhPassword')

      repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
        authentication(userName: user, password: pass)
      }

      snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
        authentication(userName: user, password: pass)
      }

      pom.project {
        name 'Docker Secrets'
        packaging 'jar'
        // optionally artifactId can be defined here
        description 'A simple library to load Docker secrets in a swarm cluster as a map..'
        url 'https://github.com/carsdotcom/docker-secrets-java'

        scm {
          connection 'scm:git:https://github.com/carsdotcom/docker-secrets-java.git'
          developerConnection 'scm:git:https://github.com/carsdotcom/docker-secrets-java.git'
          url 'https://github.com/carsdotcom/docker-secrets-java'
        }

        licenses {
          license {
            name 'The Apache License, Version 2.0'
            url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
          }
        }

        developers {
          developer {
            id 'cars-user'
            name 'Deep Mistry'
            email 'dmistry@cars.com'
          }
        }
      }
    }
  }
}

nexusStaging {
  packageGroup = "com.cars"
}

task wrapper(type: Wrapper) { gradleVersion = '2.12' }

task osshrRelease << { println "Archives uploaded and released!" }

osshrRelease.dependsOn uploadArchives
osshrRelease.dependsOn closeRepository
osshrRelease.dependsOn releaseRepository
closeRepository.mustRunAfter uploadArchives
releaseRepository.mustRunAfter closeRepository

tasks.release.finalizedBy tasks.osshrRelease