build.gradle

plugins {
    id "java"
    id "maven-publish"
    id "signing"
    id "checkstyle"
    id "jacoco"
    id "org.embulk.embulk-plugins" version "0.5.5"
}

repositories {
    mavenCentral()

    maven {
        url = uri("https://maven.pkg.github.com/calorie/jackson-datatype-msgpack")
        credentials {
            username = project.findProperty("gpr.user") ?: System.getenv("PACKAGE_USERNAME")
            password = project.findProperty("gpr.key") ?: System.getenv("PACKAGE_TOKEN")
        }
    }
}

group = "org.embulk"
version = "1.1.6-SNAPSHOT"
description = "OpenSearch output plugin is an Embulk plugin that loads records to OpenSearch read by any input plugins."

sourceCompatibility = JavaVersion.VERSION_11
targetCompatibility = JavaVersion.VERSION_11

tasks.withType(JavaCompile) {
    options.compilerArgs << "-Xlint:deprecation" << "-Xlint:unchecked"
    options.encoding = "UTF-8"
}

java {
    withJavadocJar()
    withSourcesJar()
}

dependencies {
    compileOnly "org.embulk:embulk-api:0.10.41"
    compileOnly "org.embulk:embulk-spi:0.10.41"

    implementation("org.embulk:embulk-util-config:0.3.3") {
        // They conflict with embulk-core. They are once excluded here,
        // and added explicitly with versions exactly the same with embulk-core:0.10.41.
        exclude group: "com.fasterxml.jackson.core", module: "jackson-annotations"
        exclude group: "com.fasterxml.jackson.core", module: "jackson-core"
        exclude group: "com.fasterxml.jackson.core", module: "jackson-databind"
        exclude group: "com.fasterxml.jackson.datatype", module: "jackson-datatype-jdk8"
        exclude group: "javax.validation", module: "validation-api"
    }

    // They are once excluded from transitive dependencies of other dependencies,
    // and added explicitly with versions exactly the same with embulk-core:0.10.41.
    implementation "com.fasterxml.jackson.core:jackson-annotations:2.6.7"
    implementation "com.fasterxml.jackson.core:jackson-core:2.6.7"
    implementation "com.fasterxml.jackson.core:jackson-databind:2.6.7.5" // backport security fixes.
    implementation "com.fasterxml.jackson.datatype:jackson-datatype-jdk8:2.6.7"
    implementation "javax.validation:validation-api:1.1.0.Final"

    implementation 'com.fasterxml.jackson.datatype:jackson-datatype-msgpack:0.1.1'
    implementation 'jakarta.xml.bind:jakarta.xml.bind-api:2.3.3'
    implementation "org.embulk:embulk-base-restclient:0.10.1"
    implementation "org.embulk:embulk-util-retryhelper:0.8.2"
    implementation "org.embulk:embulk-util-timestamp:0.2.1"
    implementation 'org.msgpack:msgpack-core:0.9.3'
    implementation 'org.opensearch.client:opensearch-rest-client:2.6.0'
    implementation 'org.opensearch.client:opensearch-java:2.3.0'

    testImplementation "junit:junit:4.13.2"
    testImplementation "org.hamcrest:hamcrest:2.2"
    testImplementation "com.google.guava:guava:31.1-jre"
    testImplementation "org.embulk:embulk-core:0.10.41"
    testImplementation "org.embulk:embulk-junit4:0.10.41"
    testImplementation "org.embulk:embulk-deps:0.10.41"
    testImplementation "org.embulk:embulk-parser-csv:0.10.41"
}

embulkPlugin {
    mainClass = "org.embulk.output.opensearch.OpenSearchOutputPlugin"
    category = "output"
    type = "opensearch"
}

javadoc {
    options {
        locale = "en_US"
        encoding = "UTF-8"
    }
}

jar {
    metaInf {
        from rootProject.file("LICENSE")
        from rootProject.file("NOTICE")
    }
}

sourcesJar {
    metaInf {
        from rootProject.file("LICENSE")
        from rootProject.file("NOTICE")
    }
}

javadocJar {
    metaInf {
        from rootProject.file("LICENSE")
        from rootProject.file("NOTICE")
    }
}

publishing {
    publications {
        maven(MavenPublication) {
            groupId = project.group
            artifactId = project.name

            from components.java  // Must be "components.java". The dependency modification works only for it.
            // javadocJar and sourcesJar are added by java.withJavadocJar() and java.withSourcesJar() above.
            // See: https://docs.gradle.org/current/javadoc/org/gradle/api/plugins/JavaPluginExtension.html

            pom {  // https://central.sonatype.org/pages/requirements.html
                packaging "jar"

                name = project.name
                description = project.description
                url = "https://www.embulk.org/"

                licenses {
                    license {
                        // http://central.sonatype.org/pages/requirements.html#license-information
                        name = "The Apache License, Version 2.0"
                        url = "https://www.apache.org/licenses/LICENSE-2.0.txt"
                    }
                }

                developers {
                    developer {
                        name = "Muga Nishizawa"
                        email = "muga.nishizawa@gmail.com"
                    }
                    developer {
                        name = "Sadayuki Furuhashi"
                        email = "frsyuki@gmail.com"
                    }
                    developer {
                        name = "hirakiuc"
                        email = "hirakiuc@gmail.com"
                    }
                    developer {
                        name = "Toyama Hiroshi"
                        email = "toyama0919@gmail.com"
                    }
                    developer {
                        name = "Satoshi Akama"
                        email = "satoshiakama@gmail.com"
                    }
                    developer {
                        name = "Kevin M Fitzgerald"
                        email = "kevin@kevinfitzgerald.net"
                    }
                    developer {
                        name = "Serhii Himadieiev"
                        email = "gimadeevsv@gmail.com"
                    }
                    developer {
                        name = "Dai MIKURUBE"
                        email = "dmikurube@treasure-data.com"
                    }
                }

                scm {
                    connection = "scm:git:git://github.com/embulk/embulk-output-elasticsearch.git"
                    developerConnection = "scm:git:git@github.com:embulk/embulk-output-elasticsearch.git"
                    url = "https://github.com/embulk/embulk-output-elasticsearch"
                }
            }
        }
    }

    repositories {
        maven {  // publishMavenPublicationToMavenCentralRepository
            name = "mavenCentral"
            if (project.version.endsWith("-SNAPSHOT")) {
                url "https://oss.sonatype.org/content/repositories/snapshots"
            } else {
                url "https://oss.sonatype.org/service/local/staging/deploy/maven2"
            }

            credentials {
                username = project.hasProperty("ossrhUsername") ? ossrhUsername : ""
                password = project.hasProperty("ossrhPassword") ? ossrhPassword : ""
            }
        }
    }
}

signing {
    if (project.hasProperty("signingKey") && project.hasProperty("signingPassword")) {
        logger.lifecycle("Signing with an in-memory key.")
        useInMemoryPgpKeys(signingKey, signingPassword)
    }
    sign publishing.publications.maven
}

gem {
    authors = [ "Yu Shigetani" ]
    email = [ "s2g4t1n2@gmail.com" ]
    summary = "OpenSearch output plugin for Embulk"
    homepage = "https://github.com/calorie/embulk-output-opensearch"
    licenses = [ "Apache-2.0" ]

    from rootProject.file("LICENSE")
    from rootProject.file("NOTICE_GEM")
    rename ("NOTICE_GEM", "NOTICE")
}

gemPush {
    host = "https://rubygems.org"
}

checkstyle {
    configFile = file("${project.rootDir}/config/checkstyle/checkstyle.xml")
    toolVersion = '9.3'
}
checkstyleMain {
    configFile = file("${project.rootDir}/config/checkstyle/default.xml")
    ignoreFailures = true
}
checkstyleTest {
    configFile = file("${project.rootDir}/config/checkstyle/default.xml")
    ignoreFailures = true
}
task checkstyle(type: Checkstyle) {
    classpath = sourceSets.main.output + sourceSets.test.output
    source = sourceSets.main.allJava + sourceSets.test.allJava
}