release-aar.gradle

apply plugin: 'com.github.dcendents.android-maven'
apply plugin: 'signing'

task javadoc(type: Javadoc) {
	source = android.sourceSets.main.java.srcDirs
}

task jarJavadoc(type: Jar, dependsOn: javadoc) {
	classifier = 'javadoc'
	from javadoc.destinationDir
}

task jarSources(type: Jar) {
	classifier = 'sources'
	from android.sourceSets.main.java.srcDirs
}

artifacts {
	archives jarJavadoc
	archives jarSources
}

signing {
    sign configurations.archives
}

install {
	repositories.mavenInstaller {
		pom.project {
			name project.description
			description project.description
			url 'https://www.liferay.com/community/liferay-projects/liferay-mobile-sdk/overview'
			licenses {
				license {
					name 'LGPL 2.1'
					url 'http://opensource.org/licenses/lgpl-2.1.php'
					distribution 'repo'
				}
			}
			scm {
				url 'https://github.com/brunofarache/liferay-push'
				connection 'scm:git:git://github.com/brunofarache/liferay-push.git'
			}
			developers {
				developer {
					id 'brunofarache'
					name 'Bruno Farache'
					email 'bruno.farache@liferay.com'
				}
			}
		}
	}
}

task release(type: Copy, dependsOn: install) {
	from "$buildDir/outputs/aar"
	from "$buildDir/libs"
	from "$buildDir/poms"
	into "$buildDir/release"
	exclude "${project.name}-debug.aar"

	rename { String name ->
		name.replace("${project.name}-release", "${project.name}-${version}")
	}

	rename { String name ->
		name.replace('pom-default.xml', "${project.name}-${version}.pom")
	}

	doLast {
		signing.sign file("build/release/${project.name}-${version}.pom")
	}
}