build.gradle

buildscript {
    repositories {
        jcenter()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:1.3.0'
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.2'
		classpath 'com.github.dcendents:android-maven-gradle-plugin:1.3'
    }
}

apply plugin: 'com.android.library'

android {
	compileSdkVersion 19
	buildToolsVersion "22.0.1"

	sourceSets {
		main {
			manifest {
				srcFile 'AndroidManifest.xml'
			}
			java {
				srcDir 'src'
			}
			res {
				srcDir 'res'
			}
			assets {
				srcDir 'assets'
			}
			resources {
				srcDir 'src'
			}
			aidl {
				srcDir 'src'
			}
			jniLibs{
				srcDirs 'libs'
			}
		}
	}
}

ext {
    bintrayRepo = 'maven'
    bintrayName = 'andfix'
 
    publishedGroupId = 'com.alipay.euler'
    libraryName = 'andfix'
    artifact = 'andfix'
 
    libraryDescription = 'AndFix is a library that offer hot-fix for Android App. '
 
    siteUrl = 'https://github.com/alibaba/AndFix'
    gitUrl = 'https://github.com/alibaba/AndFix.git'
 
    libraryVersion = '0.5.0'
 
    developerId = 'supern'
    developerName = 'Supern Lee'
    developerEmail = 'supern.lee@gmail.com'
 
    licenseName = 'The Apache Software License, Version 2.0'
    licenseUrl = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
    allLicenses = ["Apache-2.0"]
}

android.libraryVariants.all { variant -> 
   task("generate${variant.name.capitalize()}Javadoc", type: Javadoc) {
     title = 'AndFix API'
     // description = ''
     source = variant.javaCompile.source 
     classpath = files(variant.javaCompile.classpath.files, project.android.getBootClasspath()) 
     options { 
       links "http://docs.oracle.com/javase/7/docs/api/" 
       linksOffline "http://d.android.com/reference","${android.sdkDirectory}/docs/reference" 
     } 
     exclude '**/BuildConfig.java' 
     exclude '**/R.java' 
     include 'com/alipay/euler/andfix/patch/PatchManager.java'
   } 
 }

apply from: 'https://raw.githubusercontent.com/attwellBrian/JCenter/master/installv1.gradle'
apply from: 'https://raw.githubusercontent.com/attwellBrian/JCenter/master/bintrayv1.gradle'