-
Notifications
You must be signed in to change notification settings - Fork 0
/
tea_leaf_common_kernels.f90
561 lines (482 loc) · 19.2 KB
/
tea_leaf_common_kernels.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
!cROWn Copyright 2014 AWE.
!
! This file is part of TeaLeaf.
!
! TeaLeaf is free software: you can redistribute it and/or modify it under
! the terms of the GNU General Public License as published by the
! Free Software Foundation, either version 3 of the License, or (at your option)
! any later version.
!
! TeaLeaf is distributed in the hope that it will be useful, but
! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
! FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
! details.
!
! You should have received a copy of the GNU General Public License along with
! TeaLeaf. If not, see http://www.gnu.org/licenses/.
!> @brief Fortran heat conduction kernel
!> @author Michael Boulton, Wayne Gaudin, Douglas Shanks
!> @details This kernel has now been changed to only include common subroutines
MODULE tea_leaf_kernel_common_module
IMPLICIT NONE
! These need to be kept consistent with the data module to avoid use statement
INTEGER,private,PARAMETER :: CHUNK_LEFT =1 &
,CHUNK_RIGHT =2 &
,CHUNK_BOTTOM =3 &
,CHUNK_TOP =4 &
,CHUNK_BACK =5 &
,CHUNK_FRONT =6 &
,EXTERNAL_FACE =-1
! 3 different options for preconditioners
INTEGER,PARAMETER :: TL_PREC_NONE = 1 &
,TL_PREC_JAC_DIAG = 2 &
,TL_PREC_JAC_BLOCK = 3
INTEGER,PRIVATE :: CONDUCTIVITY = 1 &
,RECIP_CONDUCTIVITY = 2
integer, private, parameter:: jac_block_size = 4
INTEGER(KIND=4), parameter :: block_size=1
INTEGER(KIND=4), parameter :: kstep = block_size*jac_block_size
CONTAINS
SUBROUTINE tea_leaf_kernel_init_common(x_min, &
x_max, &
y_min, &
y_max, &
z_min, &
z_max, &
halo_exchange_depth, &
chunk_neighbours, &
reflective_boundary, &
density, &
energy, &
u, &
u0, &
r, &
w, &
Kx, &
Ky, &
Kz, &
cp, &
bfp, &
Mi, &
rx, &
ry, &
rz, &
preconditioner_type, &
coef)
IMPLICIT NONE
LOGICAL :: reflective_boundary
INTEGER :: preconditioner_type
INTEGER(KIND=4):: x_min,x_max,y_min,y_max,z_min,z_max,halo_exchange_depth
INTEGER, DIMENSION(6) :: chunk_neighbours
REAL(KIND=8), DIMENSION(x_min-halo_exchange_depth:x_max+halo_exchange_depth,&
y_min-halo_exchange_depth:y_max+halo_exchange_depth,&
z_min-halo_exchange_depth:z_max+halo_exchange_depth) :: density, energy, u, r, w, Kx, Ky, Kz, Mi, u0
REAL(KIND=8), DIMENSION(x_min:x_max,y_min:y_max,z_min:z_max) :: cp, bfp
INTEGER(KIND=4) :: coef
INTEGER(KIND=4) :: j,k,l
REAL(KIND=8) :: rx, ry, rz
!$OMP PARALLEL
!$OMP DO
DO l=z_min,z_max
DO k=y_min, y_max
DO j=x_min, x_max
u(j, k, l) = energy(j, k, l)*density(j, k, l)
u0(j, k, l) = energy(j, k, l)*density(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO
IF(coef .EQ. RECIP_CONDUCTIVITY) THEN
!$OMP DO
! use w as temp val
DO l=z_min-halo_exchange_depth,z_max+halo_exchange_depth
DO k=y_min-halo_exchange_depth,y_max+halo_exchange_depth
DO j=x_min-halo_exchange_depth,x_max+halo_exchange_depth
w(j, k, l)=1.0_8/density(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO
ELSE IF(coef .EQ. CONDUCTIVITY) THEN
!$OMP DO
DO l=z_min-halo_exchange_depth,z_max+halo_exchange_depth
DO k=y_min-halo_exchange_depth,y_max+halo_exchange_depth
DO j=x_min-halo_exchange_depth,x_max+halo_exchange_depth
w(j, k, l)=density(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO
ENDIF
!$OMP DO
DO l=z_min-halo_exchange_depth + 1,z_max+halo_exchange_depth
DO k=y_min-halo_exchange_depth + 1,y_max+halo_exchange_depth
DO j=x_min-halo_exchange_depth + 1,x_max+halo_exchange_depth
Kx(j, k, l)=(w(j-1,k ,l ) + w(j, k, l))/(2.0_8*w(j-1,k ,l )*w(j, k, l))
Ky(j, k, l)=(w(j ,k-1,l ) + w(j, k, l))/(2.0_8*w(j ,k-1,l )*w(j, k, l))
Kz(j, k, l)=(w(j ,k ,l-1) + w(j, k, l))/(2.0_8*w(j ,k ,l-1)*w(j, k, l))
ENDDO
ENDDO
ENDDO
!$OMP END DO
! Whether to apply reflective boundary conditions to all external faces
IF (reflective_boundary .eqv. .FALSE.) THEN
IF(chunk_neighbours(CHUNK_LEFT).EQ.EXTERNAL_FACE) THEN
!$OMP DO
DO l=z_min-halo_exchange_depth,z_max+halo_exchange_depth
DO k=y_min-halo_exchange_depth,y_max+halo_exchange_depth
DO j=x_min-halo_exchange_depth,x_min
Kx(j, k, l)=0.0_8
ENDDO
ENDDO
ENDDO
!$OMP END DO
ENDIF
IF(chunk_neighbours(CHUNK_RIGHT).EQ.EXTERNAL_FACE) THEN
!$OMP DO
DO l=z_min-halo_exchange_depth,z_max+halo_exchange_depth
DO k=y_min-halo_exchange_depth,y_max+halo_exchange_depth
DO j=x_max,x_max+halo_exchange_depth
Kx(j, k, l)=0.0_8
ENDDO
ENDDO
ENDDO
!$OMP END DO
ENDIF
IF(chunk_neighbours(CHUNK_BOTTOM).EQ.EXTERNAL_FACE) THEN
!$OMP DO
DO l=z_min-halo_exchange_depth,z_max+halo_exchange_depth
DO k=y_min-halo_exchange_depth,y_min
DO j=x_min-halo_exchange_depth,x_max+halo_exchange_depth
Ky(j, k, l)=0.0_8
ENDDO
ENDDO
ENDDO
!$OMP END DO
ENDIF
IF(chunk_neighbours(CHUNK_TOP).EQ.EXTERNAL_FACE) THEN
!$OMP DO
DO l=z_min-halo_exchange_depth,z_max+halo_exchange_depth
DO k=y_max,y_max+halo_exchange_depth
DO j=x_min-halo_exchange_depth,x_max+halo_exchange_depth
Ky(j, k, l)=0.0_8
ENDDO
ENDDO
ENDDO
!$OMP END DO
ENDIF
IF(chunk_neighbours(CHUNK_BACK).EQ.EXTERNAL_FACE) THEN
!$OMP DO
DO l=z_min-halo_exchange_depth,z_min
DO k=y_min-halo_exchange_depth,y_max+halo_exchange_depth
DO j=x_min-halo_exchange_depth,x_max+halo_exchange_depth
Kz(j, k, l)=0.0_8
ENDDO
ENDDO
ENDDO
!$OMP END DO
ENDIF
IF(chunk_neighbours(CHUNK_FRONT).EQ.EXTERNAL_FACE) THEN
!$OMP DO
DO l=z_max,z_max+halo_exchange_depth
DO k=y_min-halo_exchange_depth,y_max+halo_exchange_depth
DO j=x_min-halo_exchange_depth,x_max+halo_exchange_depth
Kz(j, k, l)=0.0_8
ENDDO
ENDDO
ENDDO
!$OMP END DO
ENDIF
ENDIF
IF (preconditioner_type .EQ. TL_PREC_JAC_BLOCK) THEN
CALL tea_block_init(x_min, x_max, y_min, y_max, z_min, z_max, &
halo_exchange_depth, cp, bfp, Kx, Ky, Kz, rx, ry, rz)
ELSE IF (preconditioner_type .EQ. TL_PREC_JAC_DIAG) THEN
CALL tea_diag_init(x_min, x_max, y_min, y_max, z_min, z_max, &
halo_exchange_depth, Mi, Kx, Ky, Kz, rx, ry, rz)
ENDIF
!$OMP DO
DO l=z_min,z_max
DO k=y_min,y_max
DO j=x_min,x_max
w(j, k, l) = (1.0_8 &
+ rx*(Kx(j+1, k, l) + Kx(j, k, l)) &
+ ry*(Ky(j, k+1, l) + Ky(j, k, l)) &
+ rz*(Kz(j, k, l+1) + Kz(j, k, l)))*u(j, k, l) &
- rx*(Kx(j+1, k, l)*u(j+1, k, l) + Kx(j, k, l)*u(j-1, k, l))&
- ry*(Ky(j, k+1, l)*u(j, k+1, l) + Ky(j, k, l)*u(j, k-1, l))&
- rz*(Kz(j, k, l+1)*u(j, k, l+1) + Kz(j, k, l)*u(j, k, l-1))
r(j, k, l) = u(j, k, l) - w(j, k, l)
!r(j, k, l) = u(j, k, l)! This is required to make a zero initial guess to match petsc errant behaviour
! Only works once timestep is run
ENDDO
ENDDO
ENDDO
!$OMP END DO
!$OMP END PARALLEL
END SUBROUTINE tea_leaf_kernel_init_common
! Finalise routine is used by both implementations
SUBROUTINE tea_leaf_kernel_finalise(x_min, &
x_max, &
y_min, &
y_max, &
z_min, &
z_max, &
halo_exchange_depth, &
energy, &
density, &
u)
IMPLICIT NONE
INTEGER(KIND=4):: x_min,x_max,y_min,y_max,z_min,z_max,halo_exchange_depth
REAL(KIND=8), DIMENSION(x_min-halo_exchange_depth:x_max+halo_exchange_depth,&
y_min-halo_exchange_depth:y_max+halo_exchange_depth,&
z_min-halo_exchange_depth:z_max+halo_exchange_depth) :: u, energy, density
INTEGER(KIND=4) :: j, k, l
!$OMP PARALLEL
!$OMP DO
DO l=z_min,z_max
DO k=y_min, y_max
DO j=x_min, x_max
energy(j, k, l) = u(j, k, l) / density(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO
!$OMP END PARALLEL
END SUBROUTINE tea_leaf_kernel_finalise
SUBROUTINE tea_leaf_calc_residual(x_min, &
x_max, &
y_min, &
y_max, &
z_min, &
z_max, &
halo_exchange_depth,&
u , &
u0, &
r, &
Kx, Ky, Kz, rx, ry, rz)
IMPLICIT NONE
INTEGER(KIND=4):: x_min,x_max,y_min,y_max,z_min,z_max,halo_exchange_depth
REAL(KIND=8), DIMENSION(x_min-halo_exchange_depth:x_max+halo_exchange_depth,&
y_min-halo_exchange_depth:y_max+halo_exchange_depth,&
z_min-halo_exchange_depth:z_max+halo_exchange_depth) :: Kx, u, r, Ky, u0, Kz
REAL(KIND=8) :: smvp, rx, ry, rz
INTEGER(KIND=4) :: j, k, l
!$OMP PARALLEL PRIVATE(smvp)
!$OMP DO
DO l=z_min,z_max
DO k=y_min, y_max
DO j=x_min, x_max
smvp = (1.0_8 &
+ rx*(Kx(j+1, k, l) + Kx(j, k, l)) &
+ ry*(Ky(j, k+1, l) + Ky(j, k, l)) &
+ rz*(Kz(j, k, l+1) + Kz(j, k, l)))*u(j, k, l) &
- rx*(Kx(j+1, k, l)*u(j+1, k, l) + Kx(j, k, l)*u(j-1, k, l))&
- ry*(Ky(j, k+1, l)*u(j, k+1, l) + Ky(j, k, l)*u(j, k-1, l))&
- rz*(Kz(j, k, l+1)*u(j, k, l+1) + Kz(j, k, l)*u(j, k, l-1))
r(j, k, l) = u0(j, k, l) - smvp
ENDDO
ENDDO
ENDDO
!$OMP END DO
!$OMP END PARALLEL
END SUBROUTINE tea_leaf_calc_residual
SUBROUTINE tea_leaf_calc_2norm_kernel(x_min, &
x_max, &
y_min, &
y_max, &
z_min, &
z_max, &
halo_exchange_depth,&
arr, &
norm)
IMPLICIT NONE
INTEGER(KIND=4):: x_min,x_max,y_min,y_max,z_min,z_max,halo_exchange_depth
REAL(KIND=8), DIMENSION(x_min-halo_exchange_depth:x_max+halo_exchange_depth,&
y_min-halo_exchange_depth:y_max+halo_exchange_depth,&
z_min-halo_exchange_depth:z_max+halo_exchange_depth) :: arr
REAL(KIND=8) :: norm
INTEGER :: j, k, l
norm = 0.0_8
!$OMP PARALLEL
!$OMP DO REDUCTION(+:norm)
DO l=z_min,z_max
DO k=y_min,y_max
DO j=x_min,x_max
norm = norm + arr(j, k, l)*arr(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO
!$OMP END PARALLEL
END SUBROUTINE tea_leaf_calc_2norm_kernel
SUBROUTINE tea_diag_init(x_min, &
x_max, &
y_min, &
y_max, &
z_min, &
z_max, &
halo_exchange_depth,&
Mi, &
Kx, Ky, Kz, rx, ry, rz)
IMPLICIT NONE
INTEGER(KIND=4):: j, k, l
INTEGER(KIND=4):: x_min,x_max,y_min,y_max,z_min,z_max,halo_exchange_depth
REAL(KIND=8), DIMENSION(x_min-halo_exchange_depth:x_max+halo_exchange_depth,&
y_min-halo_exchange_depth:y_max+halo_exchange_depth,&
z_min-halo_exchange_depth:z_max+halo_exchange_depth) :: Kx, Ky, Kz, Mi
REAL(KIND=8) :: rx, ry, rz
!$OMP DO
DO l=z_min,z_max
DO k=y_min,y_max
DO j=x_min,x_max
Mi(j, k, l) = 1.0_8/(1.0_8 + rx*(Kx(j+1, k, l ) + Kx(j, k, l)) + ry*(Ky(j, k+1, l ) &
+ Ky(j, k, l)) + rz*(Kz(j, k, l+1) + Kz(j, k, l)))
ENDDO
ENDDO
ENDDO
!$OMP END DO
END SUBROUTINE
SUBROUTINE tea_diag_solve(x_min, &
x_max, &
y_min, &
y_max, &
z_min, &
z_max, &
halo_exchange_depth,&
r, &
z, &
Mi)
IMPLICIT NONE
INTEGER(KIND=4):: j, k, l
INTEGER(KIND=4):: x_min,x_max,y_min,y_max,z_min,z_max,halo_exchange_depth
REAL(KIND=8), DIMENSION(x_min-halo_exchange_depth:x_max+halo_exchange_depth,&
y_min-halo_exchange_depth:y_max+halo_exchange_depth,&
z_min-halo_exchange_depth:z_max+halo_exchange_depth) :: r, z, Mi
!$OMP DO
DO l=z_min,z_max
DO k=y_min,y_max
DO j=x_min,x_max
z(j, k, l) = Mi(j, k, l)*r(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO NOWAIT
END SUBROUTINE
SUBROUTINE tea_block_init(x_min, &
x_max, &
y_min, &
y_max, &
z_min, &
z_max, &
halo_exchange_depth,&
cp, &
bfp, &
Kx, Ky, Kz, rx, ry, rz)
IMPLICIT NONE
INTEGER(KIND=4):: j, k, l, ko, bottom, top
INTEGER(KIND=4):: x_min,x_max,y_min,y_max,z_min,z_max,halo_exchange_depth
REAL(KIND=8), DIMENSION(x_min-halo_exchange_depth:x_max+halo_exchange_depth,&
y_min-halo_exchange_depth:y_max+halo_exchange_depth,&
z_min-halo_exchange_depth:z_max+halo_exchange_depth) :: Kx, Ky, Kz
REAL(KIND=8), DIMENSION(x_min:x_max,y_min:y_max,z_min:z_max) :: cp, bfp
REAL(KIND=8) :: rx, ry, rz
!$OMP DO
DO l=z_min,z_max
DO ko=y_min,y_max,jac_block_size
bottom = ko
top = MIN(ko + jac_block_size - 1, y_max)
#if defined(WITH_OMP4)
!$OMP SIMD
#endif
DO j=x_min, x_max
k = bottom
cp(j, k, l) = (-Ky(j, k+1, l)*ry)/(1.0_8 + rx*(Kx(j+1, k, l ) + Kx(j, k, l)) &
+ ry*(Ky(j, k+1, l ) + Ky(j, k, l)) + rz*(Kz(j, k, l+1) + Kz(j, k, l)))
DO k=bottom+1,top
bfp(j, k, l) = 1.0_8/((1.0_8 + rx*(Kx(j+1, k, l ) + Kx(j, k, l)) + ry*(Ky(j, k+1, l )&
+ Ky(j, k, l)) + rz*(Kz(j, k, l+1) + Kz(j, k, l))) - (-Ky(j, k, l)*ry)*cp(j, k-1, l))
cp(j, k, l) = (-Ky(j, k+1, l)*ry)*bfp(j, k, l)
ENDDO
ENDDO
ENDDO
ENDDO
!$OMP END DO
END SUBROUTINE
SUBROUTINE tea_block_solve(x_min, &
x_max, &
y_min, &
y_max, &
z_min, &
z_max, &
halo_exchange_depth,&
r, &
z, &
cp, &
bfp, &
Kx, Ky, Kz, rx, ry, rz)
IMPLICIT NONE
INTEGER(KIND=4):: j, k, l, ko, bottom, top, ki, upper_k, k_extra
INTEGER(KIND=4):: x_min,x_max,y_min,y_max,z_min,z_max,halo_exchange_depth
REAL(KIND=8), DIMENSION(x_min-halo_exchange_depth:x_max+halo_exchange_depth,&
y_min-halo_exchange_depth:y_max+halo_exchange_depth,&
z_min-halo_exchange_depth:z_max+halo_exchange_depth) :: Kx, Ky, Kz, r, z
REAL(KIND=8), DIMENSION(x_min:x_max,y_min:y_max,z_min:z_max) :: cp, bfp
REAL(KIND=8) :: rx, ry, rz
REAL(KIND=8), dimension(0:jac_block_size-1) :: dp_l, z_l
k_extra = y_max - MOD(y_max, kstep)
!$OMP DO
DO l=z_min,z_max
DO ko=y_min, k_extra, kstep
upper_k = ko+kstep - jac_block_size
DO ki=ko,upper_k,jac_block_size
bottom = ki
top = ki+jac_block_size - 1
#if defined(WITH_OMP4)
!$OMP SIMD PRIVATE(dp_l, z_l)
#endif
DO j=x_min,x_max
k = bottom
dp_l(k-bottom) = r(j, k, l)/(1.0_8 + rx*(Kx(j+1, k, l ) + Kx(j, k, l)) &
+ ry*(Ky(j, k+1, l ) + Ky(j, k, l)) + rz*(Kz(j, k, l+1) + Kz(j, k, l)))
DO k=bottom+1,top
dp_l(k-bottom) = (r(j, k, l) - (-Ky(j, k, l)*ry)*dp_l(k-bottom-1))*bfp(j, k, l)
ENDDO
k=top
z_l(k-bottom) = dp_l(k-bottom)
DO k=top-1, bottom, -1
z_l(k-bottom) = dp_l(k-bottom) - cp(j, k, l)*z_l(k-bottom+1)
ENDDO
DO k=bottom,top
z(j, k, l) = z_l(k-bottom)
ENDDO
ENDDO
ENDDO
ENDDO
DO ki=k_extra+1, y_max, jac_block_size
bottom = MIN(ki, y_max)
top = MIN(ki+jac_block_size-1, y_max)
#if defined(WITH_OMP4)
!$OMP SIMD PRIVATE(dp_l, z_l)
#endif
DO j=x_min,x_max
k = bottom
dp_l(k-bottom) = r(j, k, l)/(1.0_8 + rx*(Kx(j+1, k, l ) + Kx(j, k, l)) &
+ ry*(Ky(j, k+1, l ) + Ky(j, k, l)) + rz*(Kz(j, k, l+1) + Kz(j, k, l)))
DO k=bottom+1,top
dp_l(k-bottom) = (r(j, k, l) - (-Ky(j, k, l)*ry)*dp_l(k-bottom-1))*bfp(j, k, l)
ENDDO
k=top
z_l(k-bottom) = dp_l(k-bottom)
DO k=top-1, bottom, -1
z_l(k-bottom) = dp_l(k-bottom) - cp(j, k, l)*z_l(k-bottom+1)
ENDDO
DO k=bottom,top
z(j, k, l) = z_l(k-bottom)
ENDDO
ENDDO
ENDDO
ENDDO
!$OMP END DO
END SUBROUTINE
END MODULE tea_leaf_kernel_common_module