build.gradle

/*
 * Copyright 2018 Sumo Logic
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

import java.util.regex.Matcher

buildscript {
  dependencies {
    classpath "net.rdrei.android.buildtimetracker:gradle-plugin:0.11.+"
  }
}

plugins {
  id 'nebula.maven-publish' version '5.1.0'
}

apply plugin: "build-time-tracker"

def pom = new XmlParser().parse(file("$rootDir/pom.xml"))

// load properties from pom.xml, e.g. 'scala.compat.version' -> '2.11'
def pomProps = [:]
pom.properties.'*'.each { prop -> pomProps.put(prop.name().localPart, prop.text()) }

// resolve properties, e.g. '${scala.compat.version}.11 -> '2.11.11'
def resolveProps (s, props) {
  if (s =~ ~/.*\$\{(.+)}.*/) {
    def match = Matcher.lastMatcher[0][1]
    return resolveProps(s.replace("\${$match}", props[match]), props)
  }
  return s
}

def javaSourceVersion = resolveProps(pomProps['maven.compiler.source'], pomProps)
def javaTargetVersion = resolveProps(pomProps['maven.compiler.target'], pomProps)

allprojects {
  apply plugin: 'idea'
  apply plugin: 'nebula.maven-publish'
  apply plugin: 'nebula.maven-resolved-dependencies'

  group = epigraphGroup
  version = epigraphVersion

  pom.dependencyManagement.dependencies.dependency.each { dep ->
    def version = resolveProps("${dep.groupId.text()}:${dep.artifactId.text()}:${dep.version.text()}", pomProps)
//    println "${dep.groupId.text()}:${dep.artifactId.text()}:${dep.version.text()} -> $version"
    configurations.all {
      // https://github.com/typesafehub/zinc/issues/87#issuecomment-139236549
      if (it.name != 'zinc') {
        resolutionStrategy {
          force version
        }
      }
    }
  }
}

subprojects {
  repositories {
    mavenCentral()
    jcenter()
  }

  tasks.withType(JavaCompile) {
    sourceCompatibility = javaSourceVersion
    targetCompatibility = javaTargetVersion
    options.encoding = 'UTF-8'
    options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation" << "-Xdiags:verbose"
  }

  tasks.withType(ScalaCompile) {
    sourceCompatibility = javaSourceVersion
    targetCompatibility = javaTargetVersion

    ScalaCompileOptions.metaClass.daemonServer = true
    ScalaCompileOptions.metaClass.fork = true
    ScalaCompileOptions.metaClass.useAnt = false
    ScalaCompileOptions.metaClass.useCompileDaemon = false

    options.encoding = 'UTF-8'
    scalaCompileOptions.deprecation = true
    scalaCompileOptions.unchecked = true

    scalaCompileOptions.additionalParameters = ["-explaintypes"]
  }
}

// importing gradle project from IDEA is preferred to using 'gradle idea'
idea {
  project {
    jdkName = javaSourceVersion
    languageLevel = javaSourceVersion
    vcs = 'Git'
  }
}

// bootstrap: ./gradlew -c settings-bootstrap.gradle publishGradlePlugins
task publishGradlePlugins(dependsOn: [
    ':epigraph-compiler:publishToMavenLocal',
    ':epigraph-gradle-plugin:publishToMavenLocal',
    ':epigraph-gradle-plugin-common:publishToMavenLocal',
    ':epigraph-java-core:publishToMavenLocal',
    ':epigraph-java-codegen:publishToMavenLocal',
    ':epigraph-java-data-processing:publishToMavenLocal',
    ':epigraph-java-gradle-plugin:publishToMavenLocal',
    ':epigraph-java-lang-common:publishToMavenLocal',
    ':epigraph-java-projections:publishToMavenLocal',
    ':epigraph-java-projections-psi-parser-util:publishToMavenLocal',
    ':epigraph-java-projections-schema-psi-parser:publishToMavenLocal',
    ':epigraph-java-standalone-psi-util:publishToMavenLocal',
    ':epigraph-java-schema:publishToMavenLocal',
    ':epigraph-java-schema-parser:publishToMavenLocal',
    ':epigraph-java-schema-psi-parser:publishToMavenLocal',
    ':epigraph-java-schema-psi-parser-common:publishToMavenLocal',
    ':epigraph-java-test-util:publishToMavenLocal',
    ':epigraph-java-util:publishToMavenLocal',
    ':epigraph-light-psi:publishToMavenLocal',
    ':epigraph-scala-core:publishToMavenLocal'
]) {
  description 'Bootstraps gradle build by installing necessary plugins. Usage: \n ./gradlew -c settings-bootstrap.gradle publishGradlePlugins'
}

buildtimetracker {
  reporters {
    summary {
      ordered false
      threshold 500
      shortenTaskNames false
      barstyle "unicode"
    }
  }
}