-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathsparse_ir.f90
3535 lines (3535 loc) · 117 KB
/
sparse_ir.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!----------------------------------------------------------------------
MODULE sparse_ir
!----------------------------------------------------------------------
!
IMPLICIT NONE
!
PRIVATE
!
INTEGER, PARAMETER :: DP = KIND(0d0)
REAL(KIND = DP), PARAMETER :: one = 1.0D0
REAL(KIND = DP), PARAMETER :: zero = 0.0D0
REAL(KIND = DP), PARAMETER :: pi = 4.D0*ATAN(1.D0)
COMPLEX(KIND = DP), PARAMETER :: cone = (1.0D0, 0.0D0)
COMPLEX(KIND = DP), PARAMETER :: ci = (0.0D0, 1.0D0)
COMPLEX(KIND = DP), PARAMETER :: czero = (0.0D0, 0.0D0)
!
INTERFACE decompose
MODULE PROCEDURE decompose_z, decompose_d
END INTERFACE decompose
!
INTERFACE evaluate_tau
MODULE PROCEDURE evaluate_tau_zz, evaluate_tau_dd, evaluate_tau_dz, evaluate_tau_zd
END INTERFACE evaluate_tau
!
INTERFACE evaluate_matsubara_f
MODULE PROCEDURE evaluate_matsubara_f_zz, evaluate_matsubara_f_dz
END INTERFACE evaluate_matsubara_f
!
INTERFACE evaluate_matsubara_b
MODULE PROCEDURE evaluate_matsubara_b_zz, evaluate_matsubara_b_dz
END INTERFACE evaluate_matsubara_b
!
INTERFACE fit_tau
MODULE PROCEDURE fit_tau_zz, fit_tau_dd, fit_tau_dz, fit_tau_zd
END INTERFACE fit_tau
!
INTERFACE fit_matsubara_f
MODULE PROCEDURE fit_matsubara_f_zz, fit_matsubara_f_zd
END INTERFACE fit_matsubara_f
!
INTERFACE fit_matsubara_b
MODULE PROCEDURE fit_matsubara_b_zz, fit_matsubara_b_zd
END INTERFACE fit_matsubara_b
!
INTERFACE to_dlr
MODULE PROCEDURE to_dlr_zz, to_dlr_dd, to_dlr_dz, to_dlr_zd
END INTERFACE to_dlr
!
INTERFACE evaluate_tau_from_dlr
MODULE PROCEDURE evaluate_tau_from_dlr_zz, evaluate_tau_from_dlr_dz, &
evaluate_tau_from_dlr_zd, evaluate_tau_from_dlr_dd
END INTERFACE evaluate_tau_from_dlr
!
INTERFACE evaluate_matsubara_f_from_dlr
MODULE PROCEDURE evaluate_matsubara_f_from_dlr_zz, evaluate_matsubara_f_from_dlr_dz
END INTERFACE evaluate_matsubara_f_from_dlr
!
INTERFACE evaluate_matsubara_b_from_dlr
MODULE PROCEDURE evaluate_matsubara_b_from_dlr_zz, evaluate_matsubara_b_from_dlr_dz
END INTERFACE evaluate_matsubara_b_from_dlr
!
PUBLIC :: DecomposedMatrix_z, DecomposedMatrix_d, IR
PUBLIC :: init_ir, set_beta, finalize_ir
PUBLIC :: evaluate_tau, evaluate_matsubara_f, evaluate_matsubara_b
PUBLIC :: fit_tau, fit_matsubara_f, fit_matsubara_b
PUBLIC :: to_dlr
PUBLIC :: evaluate_tau_from_dlr, evaluate_matsubara_f_from_dlr, evaluate_matsubara_b_from_dlr
!
!-----------------------------------------------------------------------
TYPE DecomposedMatrix_z
!-----------------------------------------------------------------------
!!
!! This contains a given transformation matrix and the resultants from SVD of it
!!
!
COMPLEX(KIND = DP), ALLOCATABLE :: a(:, :)
!! original matrix A
REAL(KIND = DP), ALLOCATABLE :: a_real(:, :)
!! Real part of original matrix A
REAL(KIND = DP), ALLOCATABLE :: a_imag(:, :)
!! Imaginary part of original matrix A
REAL(KIND = DP), ALLOCATABLE :: a_odd(:, :)
!! having the elements from odd rows of original matrix A
REAL(KIND = DP), ALLOCATABLE :: a_even(:, :)
!! having the elements from even rows of original matrix
REAL(KIND = DP), ALLOCATABLE :: inv_s_dl(:)
!! Inverse of dimensionless singular values
REAL(KIND = DP), ALLOCATABLE :: inv_s(:)
!! Inverse of singular values
COMPLEX(KIND = DP), ALLOCATABLE :: ut(:, :)
!! transposed matrix of U which appears in A = U \Sigma V^T
COMPLEX(KIND = DP), ALLOCATABLE :: v(:, :)
!! transposed matrix of V^T which appears in A = U \Sigma V^T
REAL(KIND = DP), ALLOCATABLE :: ut_real(:, :)
!! Real part of ut
REAL(KIND = DP), ALLOCATABLE :: ut_imag(:, :)
!! Imaginary part of ut
REAL(KIND = DP), ALLOCATABLE :: v_real(:, :)
!! Real part of v
REAL(KIND = DP), ALLOCATABLE :: v_imag(:, :)
!! Imaginary part of v
INTEGER :: m
!! number of rows of A
INTEGER :: n
!! number of columns of A
INTEGER :: ns
!! number of non-zero singular values
!
!-----------------------------------------------------------------------
END TYPE DecomposedMatrix_z
!-----------------------------------------------------------------------
!
!-----------------------------------------------------------------------
TYPE DecomposedMatrix_d
!-----------------------------------------------------------------------
!!
!! This contains a given transformation matrix and the resultants from SVD of it
!!
!
COMPLEX(KIND = DP), ALLOCATABLE :: a(:, :)
!! original matrix A
REAL(KIND = DP), ALLOCATABLE :: a_real(:, :)
!! Real part of original matrix A
REAL(KIND = DP), ALLOCATABLE :: inv_s_dl(:)
!! Inverse of dimensionless singular values
REAL(KIND = DP), ALLOCATABLE :: inv_s(:)
!! Inverse of singular values
COMPLEX(KIND = DP), ALLOCATABLE :: ut(:, :)
!! transposed matrix of U which appears in A = U \Sigma V^T
COMPLEX(KIND = DP), ALLOCATABLE :: v(:, :)
!! transposed matrix of V^T which appears in A = U \Sigma V^T
REAL(KIND = DP), ALLOCATABLE :: ut_real(:, :)
!! Real part of ut
REAL(KIND = DP), ALLOCATABLE :: v_real(:, :)
!! Real part of v
INTEGER :: m
!! number of rows of A
INTEGER :: n
!! number of columns of A
INTEGER :: ns
!! number of non-zero singular values
!
!-----------------------------------------------------------------------
END TYPE DecomposedMatrix_d
!-----------------------------------------------------------------------
!
!-----------------------------------------------------------------------
TYPE IR
!-----------------------------------------------------------------------
!!
!! This contains all the IR-basis objects,
!! such as sampling points, and basis functions
!!
!
INTEGER :: size
!! total number of IR basis functions (size of s)
INTEGER :: ntau
!! total number of sampling points of imaginary time
INTEGER :: nfreq_f
!! total number of sampling Matsubara freqs (Fermionic)
INTEGER :: nfreq_b
!! total number of sampling Matsubara freqs (Bosonic)
INTEGER :: nomega
!! total number of sampling points of real frequency
REAL(KIND = DP) :: beta
!! inverse temperature
REAL(KIND = DP) :: lambda
!! lambda = 10^{nlambda},
!! which determines maximum sampling point of real frequency
REAL(KIND = DP) :: wmax
!! maximum real frequency: wmax = lambda / beta
REAL(KIND = DP) :: eps
!! eps = 10^{-ndigit}
REAL(KIND = DP) :: eps_svd
!! This is used in the SVD fitting.
REAL(KIND = DP), ALLOCATABLE :: s(:)
!! singular values
REAL(KIND = DP), ALLOCATABLE :: tau(:)
!! sampling points of imaginary time
REAL(KIND = DP), ALLOCATABLE :: x(:)
!! This is used to get tau: tau = 5.0d-1 * beta * (x + 1.d0)
REAL(KIND = DP), ALLOCATABLE :: omega(:)
!! sampling points of real frequency
REAL(KIND = DP), ALLOCATABLE :: y(:)
!! This is used to get omega: omega = y * wmax
INTEGER, ALLOCATABLE :: freq_f(:)
!! integer part of sampling Matsubara freqs (Fermion)
INTEGER, ALLOCATABLE :: freq_b(:)
!! integer part of sampling Matsubara freqs (Boson)
REAL(KIND = DP), ALLOCATABLE :: u_data(:,:)
!! dimensionless IR-basis functions of tau
COMPLEX(KIND = DP), ALLOCATABLE :: uhat_f_data(:,:)
!! dimensionless IR-basis functions of Matsubara freqs
COMPLEX(KIND = DP), ALLOCATABLE :: uhat_b_data(:,:)
!! dimensionless IR-basis functions of Matsubara freqs
REAL(KIND = DP), ALLOCATABLE :: v_data(:,:)
!! this may be not used after getting dlr_data
REAL(KIND = DP), ALLOCATABLE :: dlr_data(:,:)
!! change-of-basis matrix from IR basis to DLR basis
!! dlr_data(i, l) = - s(l) * v_data(i, l)
TYPE(DecomposedMatrix_d) :: u
!! stores IR-basis functions of tau
!! and the resultants from SVD of it
TYPE(DecomposedMatrix_z) :: uhat_f
!! stores IR-basis functions of Matsubara freqs (F)
!! and the resultants from SVD of it
TYPE(DecomposedMatrix_z) :: uhat_b
!! stores IR-basis functions of Matsubara freqs (B)
!! and the resultants from SVD of it
TYPE(DecomposedMatrix_d) :: dlr
!! stores change-of-basis matrix
!! and the resultants from SVD of it
LOGICAL :: positive_only
!! if true, take the Matsubara frequencies
!! only from the positive region
!-----------------------------------------------------------------------
END TYPE IR
!-----------------------------------------------------------------------
!
CONTAINS
!
!-----------------------------------------------------------------------
SUBROUTINE init_ir(obj, beta, lambda, eps, s, x, freq_f, freq_b, u, uhat_f, uhat_b, y, v, dlr, eps_svd, positive_only)
!-----------------------------------------------------------------------
!!
!! This routine initializes arrays related to the IR-basis objects.
!! This routine should be called by read_ir or mk_ir_preset.
!! Do not call in other routines directly.
!!
!
TYPE(IR), INTENT(INOUT) :: obj
!! contains all the IR-basis objects
REAL(KIND = DP), INTENT(IN) :: beta
!! inverse temperature
REAL(KIND = DP), INTENT(IN) :: lambda
!! lambda = 10^{nlambda}
REAL(KIND = DP), INTENT(IN) :: eps
!! eps = 10^{-ndigit}
REAL(KIND = DP), INTENT(IN) :: s(:)
!! singular values
REAL(KIND = DP), INTENT(IN) :: x(:)
!! This is used to get tau: tau = 5.0d-1 * beta * (x + 1.d0)
REAL(KIND = DP), INTENT(IN) :: y(:)
!! This is used to get omega: omega = y * wmax
REAL(KIND = DP), INTENT(IN) :: eps_svd
!! This is used in the SVD fitting.
REAL(KIND = DP), INTENT(IN) :: u(:,:)
!! IR-basis functions of tau for beta
COMPLEX(KIND = DP), INTENT(IN) :: uhat_f(:, :)
!! stores IR-basis functions of Matsubara freqs (F) for beta
COMPLEX(KIND = DP), INTENT(IN) :: uhat_b(:, :)
!! stores IR-basis functions of Matsubara freqs (B) for beta
REAL(KIND = DP), INTENT(IN) :: v(:, :)
!! this may be not used
REAL(KIND = DP), INTENT(IN) :: dlr(:, :)
!! change-of-basis matrix from IR basis to DLR basis for beta
INTEGER, INTENT(IN) :: freq_f(:)
!! integer part of sampling Matsubara freqs (Fermion)
INTEGER, INTENT(IN) :: freq_b(:)
!! integer part of sampling Matsubara freqs (Boson)
LOGICAL, INTENT(IN), OPTIONAL :: positive_only
!! if true, take the Matsubara frequencies
!! only from the positive region
!
IF ((.NOT. PRESENT(positive_only)) .OR. (.NOT. positive_only)) THEN
obj%positive_only = .false.
ELSE
obj%positive_only = .true.
ENDIF
!
IF (ALLOCATED(obj%x)) THEN
STOP 'IR%x is already allocated. You should call finalize_ir before recalling init_ir.'
ENDIF
!
obj%size = SIZE(s)
obj%ntau = SIZE(x)
IF (.NOT. obj%positive_only) THEN
obj%nfreq_f = SIZE(freq_f)
obj%nfreq_b = SIZE(freq_b)
ELSE
obj%nfreq_f = SIZE(freq_f) / 2
obj%nfreq_b = (SIZE(freq_b)-1) / 2 + 1
ENDIF
obj%lambda = lambda
obj%eps = eps
obj%eps_svd = eps_svd
obj%nomega = SIZE(y)
!
ALLOCATE(obj%x(obj%ntau))
obj%x = x
!
ALLOCATE(obj%tau(obj%ntau))
!
ALLOCATE(obj%s(obj%size))
obj%s = SQRT(5.0d-1*obj%lambda) * s
!
ALLOCATE(obj%freq_f(obj%nfreq_f))
!
ALLOCATE(obj%freq_b(obj%nfreq_b))
!
IF (.NOT. obj%positive_only) THEN
obj%freq_f = freq_f
obj%freq_b = freq_b
ELSE
obj%freq_f(1:obj%nfreq_f) = freq_f((SIZE(freq_f) / 2 + 1):SIZE(freq_f))
obj%freq_b(1:obj%nfreq_b) = freq_b(((SIZE(freq_b) + 1) / 2):SIZE(freq_b))
ENDIF
!
ALLOCATE(obj%u_data(obj%ntau, obj%size))
obj%u_data = u
!
ALLOCATE(obj%uhat_f_data(obj%nfreq_f, obj%size))
!
ALLOCATE(obj%uhat_b_data(obj%nfreq_b, obj%size))
!
IF (.NOT. obj%positive_only) THEN
obj%uhat_f_data = uhat_f
obj%uhat_b_data = uhat_b
ELSE
obj%uhat_f_data(1:obj%nfreq_f, :) = uhat_f((SIZE(freq_f) / 2 + 1):SIZE(freq_f), :)
obj%uhat_b_data(1:obj%nfreq_b, :) = uhat_b(((SIZE(freq_b) + 1) / 2):SIZE(freq_b), :)
ENDIF
!
ALLOCATE(obj%y(obj%nomega))
obj%y = y
!
ALLOCATE(obj%omega(obj%nomega))
!
ALLOCATE(obj%v_data(obj%nomega, obj%size))
obj%v_data = v
!
ALLOCATE(obj%dlr_data(obj%size, obj%nomega))
obj%dlr_data = TRANSPOSE(dlr)
!
obj%u = decompose(obj%u_data, obj%eps_svd, .false.)
IF (.NOT. obj%positive_only) THEN
obj%uhat_f = decompose(obj%uhat_f_data, obj%eps_svd, .false.)
obj%uhat_b = decompose(obj%uhat_b_data, obj%eps_svd, .false.)
ELSE
obj%uhat_f = split_decompose(obj%uhat_f_data, .false., obj%eps_svd, .false.)
obj%uhat_b = split_decompose(obj%uhat_b_data, .true., obj%eps_svd, .false.)
ENDIF
!
obj%dlr = decompose(obj%dlr_data, obj%eps_svd, .true.)
!
! Here we define basis sets for the input value of beta.
CALL set_beta(obj, beta)
!
!-----------------------------------------------------------------------
END SUBROUTINE init_ir
!-----------------------------------------------------------------------
!
!-----------------------------------------------------------------------
SUBROUTINE set_beta(obj, beta)
!-----------------------------------------------------------------------
!!
!! This routine update IR-basis objects for a given beta.
!! This is called in init_ir at once.
!!
!
TYPE(IR), INTENT(INOUT) :: obj
!! contains all the IR-basis objects
REAL(KIND = DP), INTENT(IN) :: beta
!! inverse temperature
!
obj%beta = beta
obj%wmax = obj%lambda / beta
!
obj%tau = 5.0d-1 * beta * (obj%x + 1.d0)
obj%omega = obj%y * obj%wmax
!
obj%u%a_real(:, :) = SQRT(2.0D0/beta)*obj%u_data(:, :)
obj%uhat_f%a(:, :) = SQRT(beta) * obj%uhat_f_data(:, :)
obj%uhat_b%a(:, :) = SQRT(beta) * obj%uhat_b_data(:, :)
obj%dlr%a(:, :) = SQRT(5.0d-1*beta)*obj%dlr_data(:, :)
!
obj%u%a = CMPLX(obj%u%a_real, zero, KIND = DP)
obj%uhat_f%a_real = REAL(obj%uhat_f%a, KIND = DP)
obj%uhat_f%a_imag = AIMAG(obj%uhat_f%a)
obj%uhat_b%a_real = REAL(obj%uhat_b%a, KIND = DP)
obj%uhat_b%a_imag = AIMAG(obj%uhat_b%a)
obj%uhat_f%a_odd(:, :) = obj%uhat_f%a_imag(:, 1:(obj%uhat_f%n - 1):2)
obj%uhat_f%a_even(:, :) = obj%uhat_f%a_real(:, 2:obj%uhat_f%n:2)
obj%uhat_b%a_odd(:, :) = obj%uhat_b%a_real(:, 1:(obj%uhat_b%n - 1):2)
obj%uhat_b%a_even(:, :) = obj%uhat_b%a_imag(:, 2:obj%uhat_b%n:2)
!
obj%u%inv_s(:) = SQRT(5.0d-1*beta) * obj%u%inv_s_dl(:)
obj%uhat_f%inv_s(:) = (1.0D0 / SQRT(beta)) * obj%uhat_f%inv_s_dl(:)
obj%uhat_b%inv_s(:) = (1.0D0 / SQRT(beta)) * obj%uhat_b%inv_s_dl(:)
obj%dlr%inv_s(:) = SQRT(2.0D0 / beta) * obj%dlr%inv_s_dl(:)
!
!-----------------------------------------------------------------------
END SUBROUTINE set_beta
!-----------------------------------------------------------------------
!
!-----------------------------------------------------------------------
SUBROUTINE finalize_ir(obj)
!-----------------------------------------------------------------------
!!
!! This routine deallocates IR-basis objects contained in obj
!!
!
TYPE(IR) :: obj
!! contains all the IR-basis objects
!
IF (ALLOCATED(obj%x)) DEALLOCATE(obj%x)
IF (ALLOCATED(obj%tau)) DEALLOCATE(obj%tau)
IF (ALLOCATED(obj%s)) DEALLOCATE(obj%s)
IF (ALLOCATED(obj%freq_f)) DEALLOCATE(obj%freq_f)
IF (ALLOCATED(obj%freq_b)) DEALLOCATE(obj%freq_b)
IF (ALLOCATED(obj%u_data)) DEALLOCATE(obj%u_data)
IF (ALLOCATED(obj%uhat_f_data)) DEALLOCATE(obj%uhat_f_data)
IF (ALLOCATED(obj%uhat_b_data)) DEALLOCATE(obj%uhat_b_data)
IF (ALLOCATED(obj%y)) DEALLOCATE(obj%y)
IF (ALLOCATED(obj%omega)) DEALLOCATE(obj%omega)
IF (ALLOCATED(obj%v_data)) DEALLOCATE(obj%v_data)
IF (ALLOCATED(obj%dlr_data)) DEALLOCATE(obj%dlr_data)
!
CALL finalize_dmat_d(obj%u)
CALL finalize_dmat_z(obj%uhat_f)
CALL finalize_dmat_z(obj%uhat_b)
CALL finalize_dmat_d(obj%dlr)
!-----------------------------------------------------------------------
END SUBROUTINE finalize_ir
!-----------------------------------------------------------------------
!
!-----------------------------------------------------------------------
SUBROUTINE finalize_dmat_z(dmat)
!-----------------------------------------------------------------------
!!
!! This routine deallocates arrays contained in dmat
!!
!
TYPE(DecomposedMatrix_z) :: dmat
!! contains a given transformation matrix and the resultants from SVD of it
!
IF (ALLOCATED(dmat%a)) DEALLOCATE(dmat%a)
IF (ALLOCATED(dmat%a_real)) DEALLOCATE(dmat%a_real)
IF (ALLOCATED(dmat%a_imag)) DEALLOCATE(dmat%a_imag)
IF (ALLOCATED(dmat%a_odd)) DEALLOCATE(dmat%a_odd)
IF (ALLOCATED(dmat%a_even)) DEALLOCATE(dmat%a_even)
IF (ALLOCATED(dmat%inv_s)) DEALLOCATE(dmat%inv_s)
IF (ALLOCATED(dmat%inv_s_dl)) DEALLOCATE(dmat%inv_s_dl)
IF (ALLOCATED(dmat%ut)) DEALLOCATE(dmat%ut)
IF (ALLOCATED(dmat%v)) DEALLOCATE(dmat%v)
IF (ALLOCATED(dmat%ut_real)) DEALLOCATE(dmat%ut_real)
IF (ALLOCATED(dmat%v_real)) DEALLOCATE(dmat%v_real)
IF (ALLOCATED(dmat%ut_imag)) DEALLOCATE(dmat%ut_imag)
IF (ALLOCATED(dmat%v_imag)) DEALLOCATE(dmat%v_imag)
!
!-----------------------------------------------------------------------
END SUBROUTINE finalize_dmat_z
!-----------------------------------------------------------------------
!
!-----------------------------------------------------------------------
SUBROUTINE finalize_dmat_d(dmat)
!-----------------------------------------------------------------------
!!
!! This routine deallocates arrays contained in dmat
!!
!
TYPE(DecomposedMatrix_d) :: dmat
!! contains a given transformation matrix and the resultants from SVD of it
!
IF (ALLOCATED(dmat%a)) DEALLOCATE(dmat%a)
IF (ALLOCATED(dmat%a_real)) DEALLOCATE(dmat%a_real)
IF (ALLOCATED(dmat%inv_s)) DEALLOCATE(dmat%inv_s)
IF (ALLOCATED(dmat%inv_s_dl)) DEALLOCATE(dmat%inv_s_dl)
IF (ALLOCATED(dmat%ut)) DEALLOCATE(dmat%ut)
IF (ALLOCATED(dmat%v)) DEALLOCATE(dmat%v)
IF (ALLOCATED(dmat%ut_real)) DEALLOCATE(dmat%ut_real)
IF (ALLOCATED(dmat%v_real)) DEALLOCATE(dmat%v_real)
!
!-----------------------------------------------------------------------
END SUBROUTINE finalize_dmat_d
!-----------------------------------------------------------------------
!
!-----------------------------------------------------------------------
FUNCTION decompose_z(a, eps, ill_conditioned) result(dmat)
!-----------------------------------------------------------------------
!!
!! This routine performs SVD of complex-valued matrix a.
!! Singular values smaller than eps * the largest one are dropped.
!!
!
COMPLEX(KIND = DP), INTENT(IN) :: a(:, :)
!! original matrix a
REAL(KIND = DP), INTENT(IN) :: eps
!! threshold for singular values
LOGICAL, INTENT(IN) :: ill_conditioned
!! If true, use ZGESVD instead of ZGESDD
!
INTEGER :: i
!! Counter
INTEGER :: info
!! Error status
INTEGER :: lda
!! lda = m
INTEGER :: ldu
!! ldu = m
INTEGER :: ldvt
!! ldvt = n
INTEGER :: lwork
!! lwork = mn*mn + 3*mn (ill_conditioned = false) or 2*mn + m + n (true)
INTEGER :: m
!! number of rows of a
INTEGER :: n
!! number of columns of a
INTEGER :: mn
!! m times n
INTEGER :: ns
!! number of non-zero singular values
COMPLEX(KIND = DP), ALLOCATABLE :: a_copy(:, :)
!! copy of a
COMPLEX(KIND = DP), ALLOCATABLE :: u(:, :)
!! U in A=U \Sigma V^T
COMPLEX(KIND = DP), ALLOCATABLE :: vt(:, :)
!! V^T in A=U \Sigma V^T
COMPLEX(KIND = DP), ALLOCATABLE :: work(:)
!! arrays for ZGESDD
REAL(KIND = DP), ALLOCATABLE :: rwork(:)
!! arrays for ZGESDD
REAL(KIND = DP), ALLOCATABLE :: s(:)
!! singular values
INTEGER, ALLOCATABLE :: iwork(:)
!! arrays for ZGESDD
TYPE(DecomposedMatrix_z)::dmat
!! to contain matrix a and the resultants from SVD of it
!
IF (ALLOCATED(dmat%a)) THEN
STOP 'DMAT%a is already allocated. You should call finalize_dmat before recalling decompose.'
ENDIF
!
m = SIZE(a, 1)
n = SIZE(a, 2)
mn = min(m, n)
lda = m
ldu = m
ldvt = n
IF (.NOT. ill_conditioned) THEN
lwork = mn*mn + 3*mn
ALLOCATE(rwork((5*mn+7)*mn), iwork(8*mn))
ELSE
lwork = 2*mn + m + n
ALLOCATE(rwork(5*n))
ENDIF
ALLOCATE(work(lwork), a_copy(m,n), s(m), u(ldu,m), vt(ldvt,n))
!
a_copy(1:m, 1:n) = a(1:m, 1:n)
IF (.NOT. ill_conditioned) THEN
lwork = mn*mn + 3*mn
call ZGESDD('S', m, n, a_copy, lda, s, u, ldu, vt, ldvt, work, lwork, rwork, iwork, info)
IF (info /= 0) THEN
STOP 'Failure in ZGESDD.'
ENDIF
ELSE
lwork = 2*mn + m + n
call ZGESVD('S', 'S', m, n, a_copy, lda, s, u, ldu, vt, ldvt, work, lwork, rwork, info)
IF (info /= 0) THEN
STOP 'Failure in ZGESVD.'
ENDIF
ENDIF
!
! Number of relevant singular values s(i)/s(1) >= eps
ns = 0
DO i = 1, mn
IF (s(i)/s(1) < eps) THEN
exit
ENDIF
ns = ns + 1
ENDDO
!
ALLOCATE(dmat%a(m, n))
ALLOCATE(dmat%a_real(m, n))
ALLOCATE(dmat%a_imag(m, n))
ALLOCATE(dmat%inv_s_dl(ns))
ALLOCATE(dmat%inv_s(ns))
ALLOCATE(dmat%ut(ns, m))
ALLOCATE(dmat%ut_real(ns, m))
ALLOCATE(dmat%ut_imag(ns, m))
ALLOCATE(dmat%v(n, ns))
ALLOCATE(dmat%v_real(n, ns))
ALLOCATE(dmat%v_imag(n, ns))
ALLOCATE(dmat%a_odd(m, n/2))
ALLOCATE(dmat%a_even(m, n/2))
!
! dmat%a temporarily stores the same data of input a
dmat%a = a
dmat%inv_s_dl(1:ns) = 1.0D0 / s(1:ns)
! inv_s temporarily stores the same data of inv_s_dl
dmat%inv_s(1:ns) = dmat%inv_s_dl(1:ns)
dmat%ut(1:ns, 1:m) = CONJG(TRANSPOSE(u(1:m, 1:ns)))
dmat%v(1:n, 1:ns) = CONJG(TRANSPOSE(vt(1:ns, 1:n)))
dmat%m = SIZE(a, 1)
dmat%n = SIZE(a, 2)
dmat%ns = ns
dmat%a_odd = zero
dmat%a_even = zero
!
dmat%a_real = REAL(dmat%a, KIND = DP)
dmat%a_imag = AIMAG(dmat%a)
dmat%ut_real = REAL(dmat%ut, KIND = DP)
dmat%ut_imag = AIMAG(dmat%ut)
dmat%v_real = REAL(dmat%v, KIND = DP)
dmat%v_imag = AIMAG(dmat%v)
!
IF (.NOT. ill_conditioned) THEN
DEALLOCATE(work, a_copy, s, u, vt, rwork, iwork)
ELSE
DEALLOCATE(work, a_copy, s, u, vt, rwork)
ENDIF
!
!-----------------------------------------------------------------------
END FUNCTION decompose_z
!-----------------------------------------------------------------------
!
!-----------------------------------------------------------------------
FUNCTION decompose_d(a, eps, ill_conditioned) result(dmat)
!-----------------------------------------------------------------------
!!
!! This routine performs SVD of real-valued matrix a.
!! Singular values smaller than eps * the largest one are dropped.
!!
!
REAL(KIND = DP), INTENT(IN) :: a(:, :)
!! original matrix a
REAL(KIND = DP), INTENT(IN) :: eps
!! threshold for singular values
LOGICAL, INTENT(IN) :: ill_conditioned
!! If true, use DGESVD instead of DGESDD
!
INTEGER :: i
!! Counter
INTEGER :: info
!! Error status
INTEGER :: lda
!! lda = m
INTEGER :: ldu
!! ldu = m
INTEGER :: ldvt
!! ldvt = n
INTEGER :: lwork
!! lwork = 4*mn*mn + 7*mn (ill_conditioned = false) or 5*mn + m + n (true)
INTEGER :: m
!! number of rows of a
INTEGER :: n
!! number of columns of a
INTEGER :: mn
!! m times n
INTEGER :: ns
!! number of non-zero singular values
REAL(KIND = DP), ALLOCATABLE :: a_copy(:, :)
!! copy of a
REAL(KIND = DP), ALLOCATABLE :: u(:, :)
!! U in A=U \Sigma V^T
REAL(KIND = DP), ALLOCATABLE :: vt(:, :)
!! V^T in A=U \Sigma V^T
REAL(KIND = DP), ALLOCATABLE :: work(:)
!! arrays for ZGESDD
REAL(KIND = DP), ALLOCATABLE :: s(:)
!! singular values
INTEGER, ALLOCATABLE :: iwork(:)
!! arrays for DGESDD
TYPE(DecomposedMatrix_d)::dmat
!! to contain matrix a and the resultants from SVD of it
!
IF (ALLOCATED(dmat%a)) THEN
STOP 'DMAT%a is already allocated. You should call finalize_dmat before recalling decompose.'
ENDIF
!
m = SIZE(a, 1)
n = SIZE(a, 2)
mn = min(m, n)
lda = m
ldu = m
ldvt = n
IF (.NOT. ill_conditioned) THEN
lwork = 4*mn*mn + 7*mn
ALLOCATE(iwork(8*mn))
ELSE
lwork = 5*mn + m + n
ENDIF
ALLOCATE(work(lwork), a_copy(m,n), s(m), u(ldu,m), vt(ldvt,n))
!
a_copy(1:m, 1:n) = a(1:m, 1:n)
IF (.NOT. ill_conditioned) THEN
lwork = 4*mn*mn + 7*mn
call DGESDD('S', m, n, a_copy, lda, s, u, ldu, vt, ldvt, work, lwork, iwork, info)
IF (info /= 0) THEN
STOP 'Failure in DGESDD.'
ENDIF
ELSE
lwork = 5*mn + m + n
call DGESVD('S', 'S', m, n, a_copy, lda, s, u, ldu, vt, ldvt, work, lwork, info)
IF (info /= 0) THEN
STOP 'Failure in DGESVD.'
ENDIF
ENDIF
!
! Number of relevant singular values s(i)/s(1) >= eps
ns = 0
DO i = 1, mn
IF (s(i)/s(1) < eps) THEN
exit
ENDIF
ns = ns + 1
ENDDO
!
ALLOCATE(dmat%a(m, n))
ALLOCATE(dmat%a_real(m, n))
ALLOCATE(dmat%inv_s_dl(ns))
ALLOCATE(dmat%inv_s(ns))
ALLOCATE(dmat%ut(ns, m))
ALLOCATE(dmat%ut_real(ns, m))
ALLOCATE(dmat%v(n, ns))
ALLOCATE(dmat%v_real(n, ns))
!
! dmat%a temporarily stores the same data of input a
dmat%a_real = a
dmat%inv_s_dl(1:ns) = 1.0D0 / s(1:ns)
! inv_s temporarily stores the same data of inv_s_dl
dmat%inv_s(1:ns) = dmat%inv_s_dl(1:ns)
dmat%ut_real(1:ns, 1:m) = TRANSPOSE(u(1:m, 1:ns))
dmat%v_real(1:n, 1:ns) = TRANSPOSE(vt(1:ns, 1:n))
dmat%m = SIZE(a, 1)
dmat%n = SIZE(a, 2)
dmat%ns = ns
!
dmat%a = dmat%a_real
dmat%ut = dmat%ut_real
dmat%v = dmat%v_real
!
IF (.NOT. ill_conditioned) THEN
DEALLOCATE(work, a_copy, s, u, vt, iwork)
ELSE
DEALLOCATE(work, a_copy, s, u, vt)
ENDIF
!
!-----------------------------------------------------------------------
END FUNCTION decompose_d
!-----------------------------------------------------------------------
!
!-----------------------------------------------------------------------
FUNCTION split_decompose(a, has_zero, eps, ill_conditioned) RESULT(dmat)
!-----------------------------------------------------------------------
!!
!! This routine performs "split SVD" of uhat_f or uhat_b.
!! Singular values smaller than eps * the largest one are dropped.
!!
!! Stores a matrix "A" together with its "split SVD" form::
!!
!! A == u * s @ vT
!!
!! where "vT" is a real matrix and "u" is a complex matrix. The "split" SVD
!! form differs from the SVD in that the least squares fit has to be
!! constructed as follows:
!!
!! fit(A, x) == v / s @ REAL(CONJG(TRANSPOSE(u)) * x)
!!
!! This again allows for fast and accurate least squares fits.
!!
!! This subroutine is called if positive_only = true.
!! If s, u, and vT are obtained in this subroutine, the imaginary
!! part of (CONJG(TRANSPOSE(u)) * x) returns a non-zero
!! value indeed, but that value should be ignored.
!! Only the real part will be used in fit_matsubara_{f,b}
!! if positive_only = true.
!!
!
COMPLEX(KIND = DP), INTENT(IN) :: a(:, :)
!! original matrix a
LOGICAL, INTENT(IN) :: has_zero
!! if a is uhat_b, has_zero should be true
REAL(KIND = DP), INTENT(IN) :: eps
!! threshold for singular values
LOGICAL, INTENT(IN) :: ill_conditioned
!! If true, use DGESVD instead of DGESDD
!
INTEGER :: i
!! Counter
INTEGER :: info
!! Error status
INTEGER :: lda
!! lda = m
INTEGER :: ldu
!! ldu = m
INTEGER :: ldvt
!! ldvt = n
INTEGER :: lwork
!! lwork = 4*mn*mn + 7*mn (ill_conditioned = false) or 5*mn + m + n (true)
INTEGER :: m_half
!! number of rows of a
INTEGER :: m
!! m = 2 * m_half - 1 (has_zero = true) or 2 * m_half (false)
INTEGER :: n
!! number of columns of a
INTEGER :: mn
!! m times n
INTEGER :: ns
!! number of non-zero singular values
REAL(KIND = DP), ALLOCATABLE :: a_copy(:, :)
!! copy of a
REAL(KIND = DP), ALLOCATABLE :: u(:, :)
!! U in A=U \Sigma V^T
REAL(KIND = DP), ALLOCATABLE :: vt(:, :)
!! V^T in A=U \Sigma V^T
REAL(KIND = DP), ALLOCATABLE :: work(:)
!! arrays for ZGESDD
REAL(KIND = DP), ALLOCATABLE :: s(:)
!! singular values
COMPLEX(KIND = DP), ALLOCATABLE :: u_copy(:, :)
!! copy of u
INTEGER, ALLOCATABLE :: iwork(:)
!! arrays for DGESDD
TYPE(DecomposedMatrix_z)::dmat
!! to contain matrix a and the resultants from SVD of it
!
IF (ALLOCATED(dmat%a)) THEN
STOP 'DMAT%a is already allocated. You should call finalize_dmat before recalling decompose.'
ENDIF
!
m_half = SIZE(a, 1)
IF (has_zero) THEN
m = 2 * m_half - 1
ELSE
m = 2 * m_half
ENDIF
!
n = SIZE(a, 2)
mn = min(m, n)
lda = m
ldu = m
ldvt = n
IF (.NOT. ill_conditioned) THEN
lwork = 4*mn*mn + 7*mn
ALLOCATE(work(lwork), a_copy(m,n), s(m), u(ldu,m), vt(ldvt,n), iwork(8*mn))
ELSE
lwork = 5*mn + m + n
ALLOCATE(work(lwork), a_copy(m,n), s(m), u(ldu,m), vt(ldvt,n))
ENDIF
!
a_copy(1:m_half, 1:n) = REAL(a(1:m_half, 1:n))
!
IF (has_zero) THEN
a_copy(m_half+1:m, 1:n) = AIMAG(a(2:m_half, 1:n))
ELSE
a_copy(m_half+1:m, 1:n) = AIMAG(a(1:m_half, 1:n))
ENDIF
!
IF (.NOT. ill_conditioned) THEN
lwork = 4*mn*mn + 7*mn
call DGESDD('S', m, n, a_copy, lda, s, u, ldu, vt, ldvt, work, lwork, iwork, info)
IF (info /= 0) THEN
STOP 'Failure in DGESDD.'
ENDIF
ELSE
lwork = 5*mn + m + n
call DGESVD('S', 'S', m, n, a_copy, lda, s, u, ldu, vt, ldvt, work, lwork, info)
IF (info /= 0) THEN
STOP 'Failure in DGESVD.'
ENDIF
ENDIF
!
! Number of relevant singular values s(i)/s(1) >= eps
ns = 0
DO i = 1, mn
IF (s(i)/s(1) < eps) THEN
exit
ENDIF
ns = ns + 1
ENDDO
!
ALLOCATE(u_copy(m_half, ns))
!
IF (has_zero) THEN
u_copy(1, 1:ns) = CMPLX(u(1, 1:ns), 0.0D0, KIND = DP)
u_copy(2:m_half, 1:ns) = CMPLX(u(2:m_half, 1:ns), u(m_half+1:m, 1:ns), KIND = DP)
ELSE
u_copy(1:m_half, 1:ns) = CMPLX(u(1:m_half, 1:ns), u(m_half+1:m, 1:ns), KIND = DP)
ENDIF
!
ALLOCATE(dmat%a(m_half, n))
ALLOCATE(dmat%a_real(m_half, n))
ALLOCATE(dmat%a_imag(m_half, n))
ALLOCATE(dmat%inv_s_dl(ns))
ALLOCATE(dmat%inv_s(ns))
ALLOCATE(dmat%ut(ns, m_half))
ALLOCATE(dmat%ut_real(ns, m_half))
ALLOCATE(dmat%ut_imag(ns, m_half))
ALLOCATE(dmat%v(n, ns))
ALLOCATE(dmat%v_real(n, ns))
ALLOCATE(dmat%v_imag(n, ns))
ALLOCATE(dmat%a_odd(m_half, n/2))
ALLOCATE(dmat%a_even(m_half, n/2))
!
! dmat%a temporarily stores the same data of input a
dmat%a = a
dmat%inv_s_dl(1:ns) = 1.0D0 / s(1:ns)
! inv_s temporarily stores the same data of inv_s_dl
dmat%inv_s(1:ns) = dmat%inv_s_dl(1:ns)
dmat%ut(1:ns, 1:m_half) = CONJG(TRANSPOSE(u_copy(1:m_half, 1:ns)))
dmat%v_real(1:n, 1:ns) = TRANSPOSE(vt(1:ns, 1:n))
dmat%m = SIZE(a, 1)
dmat%n = SIZE(a, 2)
dmat%ns = ns
dmat%a_odd = zero
dmat%a_even = zero
!
dmat%a_real = REAL(dmat%a, KIND = DP)
dmat%a_imag = AIMAG(dmat%a)
dmat%ut_real = REAL(dmat%ut, KIND = DP)
dmat%ut_imag = AIMAG(dmat%ut)
dmat%v_imag = zero
dmat%v = CMPLX(dmat%v_real, zero, KIND = DP)
!
IF (.NOT. ill_conditioned) THEN
DEALLOCATE(work, a_copy, s, u, vt, iwork, u_copy)
ELSE
DEALLOCATE(work, a_copy, s, u, vt, u_copy)
ENDIF
!
!-----------------------------------------------------------------------
END FUNCTION split_decompose
!-----------------------------------------------------------------------
!
!-----------------------------------------------------------------------
SUBROUTINE evaluate_tau_zz(obj, arr, res)
!-----------------------------------------------------------------------
!!
!! This routine constructs a function onto sampling points of imaginary time
!! from the IR expansion coefficients, G_n.
!! G_m = \sum_n A_{mn} * G_n.
!! G_m is a function of imaginary time.
!! A_{mn} is the n-th basis function of m,
!! where m is a sampling point of imaginary time.
!!
!! This subroutine is called when
!! both the input and output arrays are complex arrays.
!!
!
TYPE(IR), INTENT(IN) :: obj
!! contains all the IR-basis objects
COMPLEX(KIND = DP), INTENT(IN) :: arr(:, :)
!! IR expansion coefficients
COMPLEX(KIND = DP), INTENT(OUT) :: res(:, :)
!! a function constructed from IR expansion coefficients
REAL(KIND = DP), ALLOCATABLE :: arr_tmp(:, :)
!! dummy for arr
REAL(KIND = DP), ALLOCATABLE :: res_r(:, :)
!! dummy for res
REAL(KIND = DP), ALLOCATABLE :: res_i(:, :)
!! dummy for res
INTEGER :: m
!! number of columns of res,
!! which should be number of rows of A = obj%u%a
INTEGER :: n
!! number of columns of arr,
!! which should be number of columns of A = obj%u%a
INTEGER :: l1
!! number of rows of arr
INTEGER :: l2
!! number of rows of res
!
l1 = SIZE(arr, 1)
n = SIZE(arr, 2)
l2 = SIZE(res, 1)
m = SIZE(res, 2)
IF (l1 .NE. l2) STOP 'wrong number of rows of input array.'
IF (n .NE. obj%u%n) STOP 'wrong number of columns of input array.'
IF (m .NE. obj%u%m) STOP 'wrong number of columns of output array.'
res(:, :) = czero
!
IF (.NOT. obj%positive_only) THEN
!CALL ZGEMM('n', 't', l1, m, n, cone, arr(:,:), &
! l2, obj%u%a, m, czero, res(:, :), l2)
!
ALLOCATE(arr_tmp(l1, n))
ALLOCATE(res_r(l2, m))
ALLOCATE(res_i(l2, m))
! calculate the real part
arr_tmp = REAL(arr, KIND = DP)
CALL DGEMM('n', 't', l1, m, n, one, arr_tmp(:,:), &
l2, obj%u%a_real, m, zero, res_r(:, :), l2)
!
! calculate the imaginary part
arr_tmp = AIMAG(arr)
CALL DGEMM('n', 't', l1, m, n, one, arr_tmp(:,:), &
l2, obj%u%a_real, m, zero, res_i(:, :), l2)
res = CMPLX(res_r, res_i, KIND = DP)
DEALLOCATE(arr_tmp)
DEALLOCATE(res_r)
DEALLOCATE(res_i)
ELSE
ALLOCATE(arr_tmp(l1, n))
ALLOCATE(res_r(l2, m))
! only calculate the real part
arr_tmp = REAL(arr, KIND = DP)
CALL DGEMM('n', 't', l1, m, n, one, arr_tmp(:,:), &
l2, obj%u%a_real, m, zero, res_r(:, :), l2)
res = CMPLX(res_r, zero, KIND = DP)