lock: init at 1.1.2

pkgs/by-name/lo/lock/package.nix

@@ -0,0 +1,67 @@
+{
+  lib,
+  stdenv,
+  appstream,
+  blueprint-compiler,
+  desktop-file-utils,
+  fetchFromGitHub,
+  gdk-pixbuf,
+  glib,
+  gpgme,
+  gtk4,
+  libadwaita,
+  meson,
+  ninja,
+  nix-update-script,
+  pkg-config,
+  wrapGAppsHook4,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "lock";
+  version = "1.1.2";
+
+  src = fetchFromGitHub {
+    owner = "konstantintutsch";
+    repo = "Lock";
+    rev = "refs/tags/v${finalAttrs.version}";
+    hash = "sha256-jJP3E7o9Jikvm3c/78KdA/8BPacb9c99ysgSlGoJXGs=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    appstream
+    blueprint-compiler
+    desktop-file-utils
+    glib # For `glib-compile-schemas`
+    gtk4 # For `gtk-update-icon-cache`
+    meson
+    ninja
+    pkg-config
+    wrapGAppsHook4
+  ];
+
+  buildInputs = [
+    gdk-pixbuf
+    gpgme
+    gtk4
+    libadwaita
+  ];
+
+  # https://github.com/konstantintutsch/Lock/issues/26
+  hardeningDisable = [ "format" ];
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Process data with GnuPG";
+    homepage = "https://konstantintutsch.com/Lock";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ getchoo ];
+    mainProgram = "com.konstantintutsch.Lock";
+    inherit (gpgme.meta) platforms;
+  };
+})