Blizzard3.eai

//***************************************************************************
//*
//*  Melee Template Starting AI Scripts
//*
//***************************************************************************

//===========================================================================
function PickMeleeAI takes player num, string s1, string s2, string s3 returns nothing
    local integer pick

    // easy difficulty never uses any custom AI scripts
    // that are designed to be a bit more challenging
    //
    if GetAIDifficulty(num) == AI_DIFFICULTY_NEWBIE then
        call StartMeleeAI(num,s1)
        return
    endif

    if s2 == null then
        set pick = 1
    elseif s3 == null then
        set pick = GetRandomInt(1,2)
    else
        set pick = GetRandomInt(1,3)
    endif

    if pick == 1 then
        call StartMeleeAI(num,s1)
    elseif pick == 2 then
        call StartMeleeAI(num,s2)
    else
        call StartMeleeAI(num,s3)
    endif
endfunction

//===========================================================================
function MeleeStartingAI takes nothing returns nothing
    local integer index
    local player  indexPlayer
    local race    indexRace

    set index = 0
    loop
        set indexPlayer = Player(index)
        if (GetPlayerSlotState(indexPlayer) == PLAYER_SLOT_STATE_PLAYING) then
            set indexRace = GetPlayerRace(indexPlayer)
            if (GetPlayerController(indexPlayer) == MAP_CONTROL_COMPUTER) then
                // Run a race-specific melee AI script.
                if (indexRace == RACE_HUMAN) then
                #INCLUDETABLE <$VER$\races.txt> #COND "%1" eq "HUMAN"
                    call PickMeleeAI(indexPlayer, "%2", null, null)
                #ENDINCLUDE
                elseif (indexRace == RACE_ORC) then
                #INCLUDETABLE <$VER$\races.txt> #COND "%1" eq "ORC"
                    call PickMeleeAI(indexPlayer, "%2", null, null)
                #ENDINCLUDE
                elseif (indexRace == RACE_UNDEAD) then
                #INCLUDETABLE <$VER$\races.txt> #COND "%1" eq "UNDEAD"
                    call PickMeleeAI(indexPlayer, "%2", null, null)
                #ENDINCLUDE
                    call RecycleGuardPosition(bj_ghoul[index])
                elseif (indexRace == RACE_NIGHTELF) then
                #INCLUDETABLE <$VER$\races.txt> #COND "%1" eq "ELF"
                    call PickMeleeAI(indexPlayer, "%2", null, null)
                #ENDINCLUDE
                else
                    // Unrecognized race.
                endif
                call ShareEverythingWithTeamAI(indexPlayer)
            endif
        endif

        set index = index + 1
        exitwhen index == GetBJMaxPlayers()
    endloop
    set indexPlayer = null
    set indexRace = null
endfunction