build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.2.7'
    id 'io.spring.dependency-management' version '1.1.5'
    id "org.asciidoctor.jvm.convert" version "3.3.2" // REST Docs 설정
}

group = 'kakao'
version = '0.0.1-SNAPSHOT'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
    asciidoctorExt // REST Docs 설정
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.h2database:h2'
    runtimeOnly 'org.mariadb.jdbc:mariadb-java-client'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.security:spring-security-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'

    // Gson 의존성
    implementation 'com.google.code.gson:gson:2.10.1'

    // REST Docs 의존성
    asciidoctorExt 'org.springframework.restdocs:spring-restdocs-asciidoctor'
    testImplementation 'org.springframework.restdocs:spring-restdocs-mockmvc'
}

tasks.named('test') {
    useJUnitPlatform()
}

// REST Docs 설정 시작
tasks.named('bootBuildImage') {
    builder = 'paketobuildpacks/builder-jammy-base:latest'
}

asciidoctor {   // adoc 파일 html 로 변환
    configurations 'asciidoctorExt'
    dependsOn test // 테스트 실행 후 실행
}

task copyDocument(type: Copy) {
    dependsOn asciidoctor   // asciidoctor 실행 후 실행
    doFirst {   // 실행되기 전 기존 파일 삭제
        delete("src/main/resources/static/docs")
    }
    // 위의 경로를 아래의 경로로 복사
    from file("build/docs/asciidoc/index.html") // index.html 파일만 복사
    into file("src/main/resources/static/docs")
}

build { // 프로젝트 빌드 전 copyDocument 실행
    dependsOn copyDocument
}
// REST Docs 설정 종료