build.gradle

plugins {
    id "com.github.johnrengelman.shadow" version "7.1.2" apply false
}

allprojects {
    apply plugin: 'idea'
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'

    group = 'fr.hyriode'
    version = '1.3.9-SNAPSHOT'

    java {
        withSourcesJar()
        withJavadocJar()

        toolchain {
            languageVersion = JavaLanguageVersion.of(8)
        }
    }

    configurations.all {
        // Check for updates every build
        resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
    }

    compileJava {
        sourceCompatibility = JavaVersion.VERSION_1_8
        options.encoding = 'UTF-8'
    }

    repositories {
        mavenCentral()

        maven {
            name = 'HyriAPI_maven'
            url = 'https://maven.pkg.github.com/Hyriode/HyriAPI/'

            credentials {
                username System.getenv('GITHUB_USERNAME')
                password System.getenv('GITHUB_TOKEN')
            }
        }

        maven {
            name = 'HyriSpigot_maven'
            url = 'https://maven.pkg.github.com/Hyriode/HyriSpigot/'

            credentials {
                username System.getenv('GITHUB_USERNAME')
                password System.getenv('GITHUB_TOKEN')
            }
        }

        maven {
            name = 'spigotmc-repo'
            url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/'
        }

        maven {
            name = 'sonatype'
            url = 'https://oss.sonatype.org/content/groups/public/'
        }

        maven {
            name 'elmakers-maven'
            url 'https://maven.elmakers.com/repository/'
        }
    }

    tasks.withType(Javadoc) {
        options.encoding = 'UTF-8'
    }

}

archivesBaseName = 'Hyrame'

dependencies {
    compileOnly 'fr.hyriode:spigot-impl:1.8.8-SNAPSHOT'

    api 'fr.hyriode:hyriapi:1.5.2-SNAPSHOT'
    api 'fr.hyriode:spigot-api:1.8.8-SNAPSHOT'
    api 'xyz.xenondevs:particle:1.8.1'
}

publishing {
    publications {
        maven(MavenPublication) {
            from components.java

            pom {
                groupId = project.group
                artifactId = 'hyrame'
                version = project.version
                name = 'Hyrame'
                description = 'Framework to create games and plugins easily.'
                url = 'https://github.com/Hyriode/Hyrame'
            }
        }
    }

    repositories {
        maven {
            credentials {
                username System.getenv('GITHUB_USERNAME')
                password System.getenv('GITHUB_TOKEN')
            }


            name = "Hyrame_maven"
            url = "https://maven.pkg.github.com/Hyriode/Hyrame"
        }
    }
}