Problem using Preferences with AutoConnect

[MacGyverr]

Can you be more specific on how to use AutoConnect while also using Preferences.
It looks like it worked until the sketch got to a certain size, then every OTA started corrupting both, and neither will work reliably anymore.

I don't understand how to use data1 data2 or data3 as listed in your example to be able to use Preferences and AutoConnect together.

Is there a way to simply have AutoConnect use a file in the fat or SPIFFS area to store the wifi credentials so that this is not an issue?

Or is there a way to get the size of of the data that AutoConnect is going to need and adjust boundaryOffset so that AutoConnect uses the last portion of EEPROM?

Is there a way to use "Config.autoSave = AC_SAVECREDENTIAL_NEVER" but take the current credentials and store them in EEPROM via Preferences? So that it doesn't store every credential ever used just the latest one?

Is there a way to modify the NVS area to be larger so that both can use it, is it like a normal filesystem, and if AutoConnect data is already there, will Preferences just use the space afterwards?

When I found AutoConnect it was exactly what I was looking for, it worked great, I only hope I can find a way to use both.
Thank you for the work you put into it already.

[MacGyverr]

I tried making the nvs partition larger but it screws up the hardcoded 0x10000 app start location, so in the end I just sacrificed the original location and moved nvs to before the spiffs partition and then gave it 512KB of size, this seems to give AutoConnect enough room. I also avoided using Preferences until after I set up AutoConnect. I have no idea if the order mattered or if the size helped or if it was all just a coincidence but it's working again so I'm happy. Here is the partition scheme I used in the end:

nvs2, data, nvs, 0x9000, 0x5000,
otadata, data, ota, 0xe000, 0x2000,
app0, app, ota_0, 0x10000, 0x140000,
app1, app, ota_1, 0x150000, 0x140000,
nvs, data, nvs, 0x290000, 0x7d000,
spiffs, data, spiffs, 0x30d000, 0xF3000,

[Hieromon]

My answers are also individual because your question is fragmented.

I don't understand how to use data1 data2 or data3 as listed in your example to be able to use Preferences and AutoConnect together.

Which one of my examples?

Is there a way to simply have AutoConnect use a file in the fat or SPIFFS area to store the wifi credentials so that this is not an issue?

There is no way. AutoConnect does not support it. User sketches can destroy it when you save the credentials to SPIFFS. AutoConnect cannot protect it. The only reasonable way is to partition the AutoConnect credentials by the Preference key.

Is there a way to use "Config.autoSave = AC_SAVECREDENTIAL_NEVER" but take the current credentials and store them in EEPROM via Preferences? So that it doesn't store every credential ever used just the latest one?

If you only want to enable the last credential, then with "Config.autoSave=AC_SAVECREDENTIAL_NEVER", drive the ESP-IDF API as esp_wifi_get_config directly by your sketch.
In the case where AutoConnect::begin is successful, reads the current credential using esp_wifi_get_config and saves it to your own file system. In addition, it reads the previous credentials from the file system prior to calling AutoConnect::begin and recovers using esp_wifi_set_config. However, I don't know if this logic sequence works as intended.

Is there a way to modify the NVS area to be larger so that both can use it, is it like a normal filesystem, and if AutoConnect data is already there, will Preferences just use the space afterwards?

You have already found the answer. Adjust the partition table to fit the storage area required for your sketch.
After all, AutoConnect is just a library, so I think the only way to adjust the partition table is to do the build-time configuration manually.

[MacGyverr]

Thank you for the work you put into AutoConnect and your replies.
The example in question was EEPROM.ino and it was because I didn't understand if it was replacing the data normally going into the nvs area and instead putting it in an eeprom partition and why it was for just 3 entries.
Thank you for the esp_wifi_xxx_config info.
I think the re-partitioning worked, so hopefully I won't need any other methods. It might be nice to be able to select the nvs partition that AutoConnect uses, I think there is enough nvs space for both now (at 512kb).
Thank you again. :)

[Hieromon]

The example in question was EEPROM.ino and it was because I didn't understand if it was replacing the data normally going into the nvs area and instead putting it in an eeprom partition and why it was for just 3 entries.

EEPROM.ino demonstrates the points to keep in mind when allocating the user area to EEPROM with ESP8266. AutoConnect ESP8266 version will allocate credentials area to EEPROM due to ESP8266 Arduino has no Preferences storage. The ESP8266 EEPROM library forces us to treat the entire area as page access. Therefore, for users who do not fully understand the characteristics of EEPROM, placing their own sketching data in EEPROM is an easy way to discard AutoConnect credentials. The purpose of the EEPROM.ino demonstration is to mitigate that risk. You do not need to worry about it on the ESP32 platform.

[Hieromon]

@MacGyverr

So that it doesn't store every credential ever used just the latest one?

Here is snippet:

#include <Arduino.h>
#include <WiFi.h>
#include <WebServer.h>
#include <Preferences.h>
#include <AutoConnect.h>
extern "C" {
#include <esp_wifi.h>
}

const char* PREFS_NAMESPACE = "credential";
const char* PREFS_KEY = "credential";

Preferences prefs;
wifi_config_t w_config;

AutoConnect portal;
AutoConnectConfig config;

void onConnect(IPAddress& ip) {
  esp_err_t err;

  Serial.println("WiFi connected");
  if ((err = esp_wifi_get_config(WIFI_IF_STA, &w_config)) == ESP_OK) {
    Serial.printf("%.*s: ", sizeof(wifi_config_t::sta.ssid), w_config.sta.ssid);
    if (prefs.putBytes(PREFS_KEY, &w_config, sizeof(w_config)) == sizeof(wifi_config_t))
      Serial.println("credential saved");
    else
      Serial.println("failed to save");
  }
  else
    Serial.printf("esp_wifi_get_config err(%d): %s\n", err, esp_err_to_name(err));
}

void setup() {
  delay(1000);
  Serial.begin(115200);
  WiFi.enableSTA(true);

  prefs.begin(PREFS_NAMESPACE);
  if (prefs.getBytes(PREFS_KEY, &w_config, sizeof(wifi_config_t)) == sizeof(wifi_config_t)) {
    esp_wifi_set_config(WIFI_IF_STA, &w_config);
    Serial.printf("SSID %.*s restored\n", sizeof(wifi_config_t::sta.ssid), w_config.sta.ssid);
  }
  else
    Serial.println("No available SSID saved");
  
  config.autoSave = AC_SAVECREDENTIAL_NEVER;
  portal.config(config);

  portal.onConnect(onConnect);
  portal.begin();
}

void loop() {
  portal.handleClient();
}