build.gradle

plugins {
  id "com.github.johnrengelman.shadow" version "8.1.1"
  id "java"
}

java {
  sourceCompatibility = JavaVersion.VERSION_1_8
  targetCompatibility = JavaVersion.VERSION_1_8
}

test {
  useJUnitPlatform()
}

ext.mainClass = "net.prominic.groovyls.GroovyLanguageServer"

tasks.build.dependsOn tasks.shadowJar

shadowJar {
  manifest {
    attributes "Main-Class": "net.prominic.groovyls.GroovyLanguageServer"
  }
}

repositories  {
  mavenCentral()
}

dependencies {
  implementation "org.eclipse.lsp4j:org.eclipse.lsp4j:0.12.0"
  implementation "org.eclipse.lsp4j:org.eclipse.lsp4j.jsonrpc:0.12.0"
  implementation "org.apache.groovy:groovy:4.0.5"
  implementation "com.google.code.gson:gson:2.8.7"
  implementation "io.github.classgraph:classgraph:4.8.138"
  testImplementation "org.junit.jupiter:junit-jupiter-api:5.7.2"
  testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:5.7.2"
}

// assuming that Moonshine-IDE is checked out in a folder that has the same
// parent folder as groovy-language-server, copies the built .jar file to the
// appropriate location
task deployMoonshine(type: Copy) {
    dependsOn(build)
    from "build/libs/groovy-language-server-all.jar"
    into "../Moonshine-IDE/ide/MoonshineSharedCore/src/elements/groovy-language-server/"
}
task deployMoonshineTest(type: Copy) {
    dependsOn(build)
    from "build/libs/groovy-language-server-all.jar"
    into "../Moonshine-IDE/ide/MoonshineDESKTOPevolved/bin-debug/elements/groovy-language-server/"
}