cw_split_part_delimstr_idx.sqlx

config { hasOutput: true }
/*
 * Copyright 2023 Google LLC
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

CREATE OR REPLACE FUNCTION ${self()}(value STRING, delimiter STRING, part INT64)
  RETURNS STRING
  OPTIONS(
    description="""Extract the Nth part of a string (index starts at 1). Similar to snowflake SPLIT_PART"""
  )
  AS (
     (WITH t AS (SELECT CASE WHEN delimiter = ''
                             THEN array[value]
                             ELSE split(value, delimiter) END AS s),
           n AS (SELECT CASE WHEN part = 0 THEN 1
                             WHEN part < 0 THEN ARRAY_LENGTH(s) + part + 1
                             ELSE part END AS i FROM t)
        SELECT CASE WHEN n.i < 1 OR n.i > ARRAY_LENGTH(t.s) THEN ''
	            ELSE t.s[ORDINAL(n.i)] END FROM t, n)
);