build.gradle

plugins {
    id 'fabric-loom' version '0.11-SNAPSHOT'
    id 'maven-publish'
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = project.modid
version = project.version + "-" + project.minecraft_version

repositories {
    maven { url "https://maven.fabricmc.net/" }
    maven { url 'https://jitpack.io' }
    maven { url "https://server.bbkr.space/artifactory/libs-release" }
    maven { url "https://maven.shedaniel.me/" }
    maven { url "https://maven.terraformersmc.com/"}
}

dependencies {
    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API. This is technically optional, but you probably want it anyway.
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    // Magna (https://github.com/Draylar/magna) for hammers
    include "com.github.Draylar:magna:${project.magna_version}"
    modImplementation ("com.github.Draylar:magna:${project.magna_version}") {
        exclude group: "net.fabricmc"
        exclude group: "com.jamieswhiteshirt"
        exclude group: "me.shedaniel.cloth"
    }

    // dev modmenu
    modImplementation "com.terraformersmc:modmenu:${project.mod_menu_version}"

    modImplementation ("io.github.cottonmc:StaticData:1.1.2") {
        exclude group: "net.fabricmc.fabric-api"
    }

    // Static Content (https://github.com/Draylar/static-content) for hammer loading and compat
    include "com.github.Draylar:static-content:${project.static_content_version}"
    modImplementation ("com.github.Draylar:static-content:${project.static_content_version}") {
        exclude group: "net.fabricmc"
    }

    // JIJ Maybe Data (https://github.com/Draylar/maybe-data) for optional recipes
    include "com.github.Draylar:maybe-data:${project.maybe_data_version}"
    modImplementation "com.github.Draylar:maybe-data:${project.maybe_data_version}"

    // Config solutions + Cloth Config for Magna
    modImplementation "com.github.Draylar.omega-config:omega-config-base:${project.omega_config_version}"
    include "com.github.Draylar.omega-config:omega-config-base:${project.omega_config_version}"
    modApi("me.shedaniel.cloth:cloth-config-fabric:${project.cloth_config_version}") {
        exclude(group: "net.fabricmc.fabric-api")
    }
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    // Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
    it.options.release = 17
}

java {
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}"}
    }
}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }

    // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
    repositories {
        // Add repositories to publish to here.
        // Notice: This block does NOT have the same function as the block in the top level.
        // The repositories here will be used for publishing your artifact, not for
        // retrieving dependencies.
    }
}