build.gradle

plugins {
	id "fabric-loom" version "0.6-SNAPSHOT"
	id "com.github.johnrengelman.shadow" version "5.2.0"
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
	maven {
		name = "jitpack.io"
		url = "https://jitpack.io"
	}
	maven {
		name = "lukflug"
		url = "https://lukflug.github.io/maven"
	}
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"


	compile "com.lukflug:panelstudio:0.1.8"
	modCompile "com.lukflug:panelstudio-mc16:0.1.9"
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = "UTF-8"
	def targetVersion = 8
	if (JavaVersion.current().isJava9Compatible()) {
		it.options.release = targetVersion
	}
}

java {
	withSourcesJar()
}

shadowJar {
	dependencies {
		include "com.lukflug:panelstudio"
		include "com.lukflug:panelstudio-mc16"
		include "com.github.ZeroMemes:Alpine"
	}
	classifier = "shadow"
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archivesBaseName}"}
	}
}

remapJar {
	dependsOn(shadowJar)
	input.set(shadowJar.archiveFile)
}