build.gradle

buildscript {
    repositories {
        maven { url = 'https://repo.spongepowered.org/repository/maven-public/' }
    }
    dependencies {
        classpath 'org.spongepowered:mixingradle:0.7-SNAPSHOT'
    }
}

plugins {
    id 'eclipse'
    id 'maven-publish'
    id 'net.minecraftforge.gradle' version '5.1.+'
    id 'org.parchmentmc.librarian.forgegradle' version '1.+'
}

version = '1.0'
group = 'io.github.darealturtywurty.turtychemistry'
archivesBaseName = 'turtychemistry'

java.toolchain.languageVersion = JavaLanguageVersion.of(17)

println('Java: ' + System.getProperty('java.version') + ' JVM: ' + System.getProperty('java.vm.version') + '(' + System.getProperty('java.vendor') + ') Arch: ' + System.getProperty('os.arch'))
minecraft {
    mappings channel: 'parchment', version: '2022.09.04-1.19.2'

    accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg')

    runs {
        client {
            properties 'mixin.env.remapRefMap': 'true'
            property 'mixin.env.refMapRemappingFile', "${project.projectDir}/build/createSrgToMcp/output.srg"
            workingDirectory project.file('run_client')
            arg "-mixin.config=" + archivesBaseName + ".mixins.json"

            mods {
                turtychemistry {
                    source sourceSets.main
                }
            }
        }

        server {
            properties 'mixin.env.remapRefMap': 'true'
            property 'mixin.env.refMapRemappingFile', "${project.projectDir}/build/createSrgToMcp/output.srg"
            workingDirectory project.file('run_server')
            arg "-mixin.config=" + archivesBaseName + ".mixins.json"

            mods {
                turtychemistry {
                    source sourceSets.main
                }
            }
        }

        data {
            workingDirectory project.file('run_data')

            args '--mod', archivesBaseName, '--all', '--output', file('src/generated/resources/'), '--existing', file('src/main/resources/')

            mods {
                turtychemistry {
                    source sourceSets.main
                }
            }
        }
    }
}

sourceSets.main.resources { srcDir 'src/generated/resources' }

repositories {
    flatDir {
        dir 'libs'
    }
    maven {
        name = "Progwml6 maven"
        url = "https://dvs1.progwml6.com/files/maven/"
    }
    maven {
        name = "ModMaven"
        url = "https://modmaven.dev"
    }
}

dependencies {
    minecraft 'net.minecraftforge:forge:1.19.2-43.1.3'
    annotationProcessor 'org.spongepowered:mixin:0.8.3:processor'

    implementation fg.deobf("io.github.darealturtywurty.turtylib:turtylib-1.0:0.1")

    compileOnly(fg.deobf("mezz.jei:jei-1.19.2-common-api:11.3.0.260"))
    compileOnly(fg.deobf("mezz.jei:jei-1.19.2-forge-api:11.3.0.260"))
    runtimeOnly(fg.deobf("mezz.jei:jei-1.19.2-forge:11.3.0.260"))
}

jar {
    manifest {
        attributes([
                "Specification-Title"     : "Turty's Chemistry",
                "Specification-Vendor"    : "TurtyWurty",
                "Specification-Version"   : "1",
                "Implementation-Title"    : project.name,
                "Implementation-Version"  : project.jar.archiveVersion,
                "Implementation-Vendor"   : "TurtyWurty",
                "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                "MixinConfigs"            : archivesBaseName + ".mixins.json"
        ])
    }
}

jar.finalizedBy('reobfJar')

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifact jar
        }
    }
    repositories {
        maven {
            url "file://${project.projectDir}/mcmodsrepo"
        }
    }
}

apply plugin: 'org.spongepowered.mixin'

mixin {
    add sourceSets.main, "${archivesBaseName}.refmap.json"
}