build.gradle

plugins {
    id 'java'
    id 'org.jetbrains.kotlin.jvm' version '1.7.10'
    id "org.jlleitschuh.gradle.ktlint" version '10.3.0'
}

group = 'love.chihuyu'
version = ''

repositories {
    mavenCentral()
    mavenLocal()
    maven { url = 'https://repo.purpurmc.org/snapshots' }
    maven { url = "https://repo.codemc.org/repository/maven-public/" }
    maven { url = "https://repo.convallyria.com/releases" }
}

dependencies {
    compileOnly 'org.purpurmc.purpur:purpur-api:1.19.3-R0.1-SNAPSHOT'
    compileOnly "dev.jorel:commandapi-core:8.7.1"
    implementation "com.convallyria.languagy:api:3.0.0"
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
}

ktlint {
    ignoreFailures = true
    disabledRules = ["no-wildcard-imports"]
}

def targetJavaVersion = 17
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

jar {
    from {
        duplicatesStrategy 'exclude'
        configurations.runtimeClasspath.collect {
            it.isDirectory() ? it : zipTree(it)
        }
    }
}

tasks.withType(JavaCompile).configureEach {
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release = targetJavaVersion
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}

compileKotlin {
    kotlinOptions {
        jvmTarget = "1.8"
    }
}

compileTestKotlin {
    kotlinOptions {
        jvmTarget = "1.8"
    }
}