build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

apply plugin: 'forge'

version = "0.7.8"
group= "blusunrize"
archivesBaseName = "ImmersiveEngineering"

apply plugin: 'java'
sourceCompatibility = 1.7
targetCompatibility = 1.7

minecraft {
    version = "1.7.10-10.13.4.1566-1.7.10"
	replace '${version}', project.version
    runDir = "eclipse"
}

dependencies {
	compile fileTree(dir: 'externalLibs', include: '*.jar')
}

jar {
        manifest {
        attributes 'FMLAT': 'ImmersiveEngineering_at.cfg'
    }
}

processResources
{
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

task deobfJar(type: Jar) {
	from sourceSets.main.output
	classifier = 'deobf'
	manifest {
		attributes 'FMLAT': 'ImmersiveEngineering_at.cfg'
	}
}

task apiZip(type: Zip) {
	from(sourceSets.main.java) {
		include "blusunrize/immersiveengineering/api/**"
		}	
	classifier = 'api'
}

artifacts {
	archives deobfJar
	archives apiZip
}