shadowfinder: add package

packages/shadowfinder/PKGBUILD

@@ -0,0 +1,51 @@
+# This file is part of BlackArch Linux ( https://www.blackarch.org/ ).
+# See COPYING for license details.
+
+pkgname=shadowfinder
+_pkgname=ShadowFinder
+pkgver=0.5.0.r0.g578d5ac
+pkgrel=1
+pkgdesc='Find possible locations of shadows around the world.'
+arch=('any')
+url='https://github.com/bellingcat/ShadowFinder'
+license=('MIT')
+depends=('python' 'python-basemap' 'python-matplotlib' 'python-fire' 'python-numpy' 'python-pandas' 'python-pytz' 'python-suncalc' 'python-timezonefinder')
+makedepends=('git' 'python-build' 'python-pip')
+options=(!emptydirs)
+source=("git+https://github.com/bellingcat/$_pkgname.git")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $_pkgname
+
+  ( set -o pipefail
+    git describe --long --tags --abbrev=7 2>/dev/null |
+      sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "%s.%s" "$(git rev-list --count HEAD)" \
+      "$(git rev-parse --short=7 HEAD)"
+  )
+}
+
+build() {
+  cd $_pkgname
+
+  python -m build --wheel --outdir="$startdir/dist"
+}
+
+package() {
+  cd $_pkgname
+
+  pip install \
+    --verbose \
+    --disable-pip-version-check \
+    --no-warn-script-location \
+    --ignore-installed \
+    --no-compile \
+    --no-deps \
+    --root="$pkgdir" \
+    --prefix=/usr \
+    --no-index \
+    --find-links="file://$startdir/dist" \
+    $_pkgname
+}
+