build.gradle

buildscript {
    repositories {
        mavenLocal()
        maven { url "https://nexus.ala.org.au/content/groups/public/" }
        maven { url "https://repo.grails.org/grails/core" }
    }
    dependencies {
        classpath "org.grails:grails-gradle-plugin:$grailsVersion"
        classpath "com.bertramlabs.plugins:asset-pipeline-gradle:2.14.2"
    }
}

version "1.5.3-SNAPSHOT"

group "au.org.ala.plugins.grails"

apply plugin:"eclipse"
apply plugin:"idea"
apply plugin:"org.grails.grails-plugin"
apply plugin:"org.grails.grails-plugin-publish"
apply plugin:"org.grails.grails-gsp"
apply plugin:"asset-pipeline"
apply plugin:"maven-publish"

sourceCompatibility = 1.8
targetCompatibility = 1.8


repositories {
    mavenLocal()
    maven { url "https://nexus.ala.org.au/content/groups/public/" }
    maven { url "https://repo.grails.org/grails/core" }
}

dependencies {
    compile "org.springframework.boot:spring-boot-starter-logging"
    compile "org.springframework.boot:spring-boot-autoconfigure"
    compile "org.grails:grails-core"
    compile "org.springframework.boot:spring-boot-starter-actuator"
    compile "org.springframework.boot:spring-boot-starter-tomcat"
    compile "org.grails:grails-dependencies"
    compile "org.grails:grails-web-boot"
    compile "org.grails.plugins:cache"
    //compile "org.grails.plugins:scaffolding"
    console "org.grails:grails-console"
    profile "org.grails.profiles:web-plugin"
    provided "org.grails:grails-plugin-services"
    provided "org.grails:grails-plugin-domain-class"
    compile "com.bertramlabs.plugins:asset-pipeline-grails:2.14.2"
    runtime "org.hibernate:hibernate-validator:5.4.2.Final"
    runtime "dom4j:dom4j:1.6.1"
    testCompile "org.grails:grails-plugin-testing"
    testCompile "org.grails.plugins:geb"
    testRuntime "org.seleniumhq.selenium:selenium-htmlunit-driver:2.47.1"
    testRuntime "net.sourceforge.htmlunit:htmlunit:2.18"
    testCompile 'com.stehno.ersatz:ersatz:1.9.0:safe@jar'

    compile ('org.jasig.cas.client:cas-client-core:3.4.1') {
        exclude group: 'javax.servlet', module: 'servlet-api'
    }
    compile group: 'au.org.ala', name: 'ala-name-matching-model', version: '4.1', changing: true
    compile "commons-httpclient:commons-httpclient:3.1"
    compile "org.codehaus.jackson:jackson-core-asl:1.8.6"
    compile "org.codehaus.jackson:jackson-mapper-asl:1.8.6"
    compile "org.jsoup:jsoup:1.8.3"

    compile group: 'org.grails.plugins', name: 'ala-bootstrap3', version: '3.2.3'
    compile group: 'org.grails.plugins', name: 'ala-auth', version:'3.1.3'
    compile group: 'au.org.ala.plugins.grails', name: 'ala-citation-plugin', version: '1.0'
    runtime group: 'au.org.ala.plugins.grails', name: 'ala-charts-plugin', version: '2.1.2'
    compile group: 'au.org.ala.plugins.grails', name: 'images-client-plugin', version: '1.2'
    compile "au.org.ala:data-quality-filter-service-client:1.0.0"
}

bootRun {
    jvmArgs('-Dspring.output.ansi.enabled=always')
    addResources = true
}
// enable if you wish to package this plugin as a standalone application
bootRepackage.enabled = false
grailsPublish {
    githubSlug = 'AtlasOfLivingAustralia/bie-plugin'
    websiteUrl = 'https://github.com/AtlasOfLivingAustralia/bie-plugin'
    license {
        name = 'MPL-1.1'
    }
    issueTrackerUrl = 'https://github.com/AtlasOfLivingAustralia/bie-plugin/issues'
    vcsUrl = 'https://github.com/AtlasOfLivingAustralia/bie-plugin'
    title = "BIE Plugin"
    desc = "This plugin provides the presentation layer of the BIE"
    developers = [
            davem: "Dave Martin",
            nickdr: "Nick dos Remedios",
            dougp: "Doug Palmer"
    ]
}


assets {
    packagePlugin = true
}


publishing {
    repositories {
        maven {
            name 'Nexus'
            url "https://nexus.ala.org.au/content/repositories/${project.version.endsWith('-SNAPSHOT') ? 'snapshots' : 'releases' }"
            credentials {
                username = System.getenv('TRAVIS_DEPLOY_USERNAME')
                password = System.getenv('TRAVIS_DEPLOY_PASSWORD')
            }
        }
    }
}