build.gradle

plugins {
	id 'fabric-loom' version '1.7.2'
	id 'maven-publish'
	id "io.freefair.lombok" version "8.10"
}

apply from: 'https://gist.githubusercontent.com/EnricoMessall/fb5de26a0ac26840060fd1ef45c32a5f/raw/cba2886a0fc2c95b24fc093684b4e6bfeafbd5ba/publish.gradle'

sourceCompatibility = JavaVersion.VERSION_21
targetCompatibility = JavaVersion.VERSION_21

archivesBaseName = project.archives_base_name
version = "${project.minecraft_version}-${project.mod_version}"
group = project.maven_group

repositories {
	mavenCentral()
	mavenLocal() // only used to build the mod locally
	maven { url 'https://masa.dy.fi/maven' }
	maven { url 'https://jitpack.io' }
	maven {
		url = uri("https://maven.pkg.github.com/Arematics/AdvancedChatCore")
		credentials {
			username = project.findProperty("gpr.user") ?: System.getenv("USERNAME")
			password = project.findProperty("gpr.key") ?: System.getenv("TOKEN")
		}
	}
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"
	modImplementation "fi.dy.masa.malilib:malilib-fabric-1.21:${project.malilib_version}"
	modImplementation "com.arematics:advancedchatcore:${project.advancedchat_version}"

	implementation "org.mariuszgromada.math:MathParser.org-mXparser:${project.mxparser_version}"
	include "org.mariuszgromada.math:MathParser.org-mXparser:${project.mxparser_version}"

	implementation "org.languagetool:language-en:5.5"
	// Transitive
	include "org.languagetool:language-en:5.5"
	include "org.languagetool:languagetool-core:5.5"
	include group: 'net.loomchild', name: 'segment', version: '2.0.3'
	include group: 'javax.xml.bind', name: 'jaxb-api', version: '2.3.1'
	include group: 'net.sf.trove4j', name: 'trove4j', version: '3.0.3'
	include group: 'org.jetbrains.intellij.deps', name: 'trove4j', version: '1.0.20200330'
	include group: 'javax.measure', name: 'unit-api', version: '2.1.3'
	include group: 'tech.units', name: 'indriya', version: '1.3'
	include group: 'tech.uom.lib', name: 'uom-lib-common', version: '1.1'
	include group: 'org.carrot2', name: 'morfologik-fsa', version: '2.1.7'
	include group: 'org.carrot2', name: 'morfologik-fsa-builders', version: '2.1.7'
	include group: 'org.carrot2', name: 'morfologik-speller', version: '2.1.7'
	include group: 'org.carrot2', name: 'morfologik-stemming', version: '2.1.7'
	include group: 'org.apache.opennlp', name: 'opennlp-tools', version: '1.9.3'
	include group: 'edu.washington.cs.knowitall', name: 'opennlp-chunk-models', version: '1.5'
	include group: 'edu.washington.cs.knowitall', name: 'opennlp-postag-models', version: '1.5'
	include group: 'edu.washington.cs.knowitall', name: 'opennlp-tokenize-models', version: '1.5'
	include group: 'edu.washington.cs.knowitall', name: 'opennlp-chunk-models', version: '1.5'
	include group: 'com.carrotsearch', name: 'hppc', version: '0.9.0'
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = "UTF-8"
	it.options.release = 21
}

java {
	withSourcesJar()
}

jar {
	from "LICENSE.txt"
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			// add all the jars that should be included when publishing to maven
			artifact(remapJar) {
				builtBy remapJar
			}
			artifact(sourcesJar) {
				builtBy remapSourcesJar
			}
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {

	}
}