build.gradle

apply plugin: 'java'
apply plugin: 'nexus'
apply plugin: 'eclipse'

group = 'com.trigonic'
version = '0.7-SNAPSHOT'

buildscript {
    repositories {
        mavenCentral()
    }

    dependencies {
        classpath 'org.gradle.api.plugins:gradle-nexus-plugin:0.2'
    }
}

repositories {
    mavenCentral()
    mavenLocal()
}

dependencies {
    compile 'junit:junit:4.+'
    compile 'com.google.guava:guava:13.0'
    compile "org.springframework:spring-core:3.1.2.RELEASE"
}

task packageJavadoc(type: Jar, dependsOn: 'javadoc') {
    from javadoc.destinationDir
    classifier = 'javadoc'
}

task packageSources(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
}

artifacts {
    archives jar
    archives packageJavadoc
    archives packageSources
}

modifyPom {
    project {
        name 'test-utils - Test Utilities'
        packaging 'jar'
        description 'Provides utilities for testing'
        url 'https://github.com/TrigonicSolutions/test-utils'
        inceptionYear '2011'

        parent {
            groupId 'org.sonatype.oss'
            artifactId 'oss-parent'
            version '7'
        }
 
        scm {
            url 'scm:git://github.com/TrigonicSolutions/test-utils.git'
            connection 'scm:git://github.com/TrigonicSolutions/test-utils.git'
        }
 
        licenses {
            license {
                name 'The Apache Software License, Version 2.0'
                url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                distribution 'repo'
            }
        }
 
        developers {
            developer {
                id 'akrueger'
                name 'Alan Krueger'
                email 'alan@trigonic.com'
                roles{
                    role 'Developer'
                }
                timezone '-6'
            }
        }
    }
}

task createWrapper(type: Wrapper) {
    gradleVersion = '1.2'
}